mirror of
https://gitlab.com/xCrystal/pokecrystal-board.git
synced 2024-09-09 09:51:34 -07:00
32ed487a47
# Conflicts: # audio/engine.asm # constants/gfx_constants.asm # constants/map_data_constants.asm # constants/pokemon_data_constants.asm # constants/sprite_constants.asm # constants/wram_constants.asm # data/maps/data.asm # engine/battle/ai/scoring.asm # engine/battle/core.asm # engine/battle/effect_commands.asm # engine/battle/misc.asm # engine/battle_anims/getpokeballwobble.asm # engine/breeding.asm # engine/buy_sell_toss.asm # engine/decorations.asm # engine/events/battle_tower/battle_tower.asm # engine/events/battle_tower/rules.asm # engine/events/buena.asm # engine/events/bug_contest/contest_2.asm # engine/events/daycare.asm # engine/events/dratini.asm # engine/events/halloffame.asm # engine/events/happiness_egg.asm # engine/events/kurt.asm # engine/events/lucky_number.asm # engine/events/magnet_train.asm # engine/events/overworld.asm # engine/events/pokerus/pokerus.asm # engine/events/print_unown.asm # engine/events/print_unown_2.asm # engine/events/unown_walls.asm # engine/item_effects.asm # engine/link.asm # engine/mon_menu.asm # engine/player_object.asm # engine/routines/playslowcry.asm # engine/scripting.asm # engine/search.asm # engine/search2.asm # engine/specials.asm # engine/start_menu.asm # engine/timeset.asm # home/battle_vars.asm # home/map.asm # maps/GoldenrodUndergroundSwitchRoomEntrances.asm # maps/IlexForest.asm # maps/KrissHouse2F.asm # maps/Route39Barn.asm # mobile/mobile_12_2.asm # mobile/mobile_40.asm # mobile/mobile_5f.asm # wram.asm
117 lines
1.3 KiB
NASM
117 lines
1.3 KiB
NASM
BattleCommand_Thief: ; 37492
|
|
; thief
|
|
|
|
ld a, [hBattleTurn]
|
|
and a
|
|
jr nz, .enemy
|
|
|
|
; The player needs to be able to steal an item.
|
|
|
|
call .playeritem
|
|
ld a, [hl]
|
|
and a
|
|
ret nz
|
|
|
|
; The enemy needs to have an item to steal.
|
|
|
|
call .enemyitem
|
|
ld a, [hl]
|
|
and a
|
|
ret z
|
|
|
|
; Can't steal mail.
|
|
|
|
ld [wd265], a
|
|
ld d, a
|
|
farcall ItemIsMail
|
|
ret c
|
|
|
|
ld a, [wEffectFailed]
|
|
and a
|
|
ret nz
|
|
|
|
ld a, [wLinkMode]
|
|
and a
|
|
jr z, .stealenemyitem
|
|
|
|
ld a, [wBattleMode]
|
|
dec a
|
|
ret z
|
|
|
|
.stealenemyitem
|
|
call .enemyitem
|
|
xor a
|
|
ld [hl], a
|
|
ld [de], a
|
|
|
|
call .playeritem
|
|
ld a, [wd265]
|
|
ld [hl], a
|
|
ld [de], a
|
|
jr .stole
|
|
|
|
|
|
.enemy
|
|
|
|
; The enemy can't already have an item.
|
|
|
|
call .enemyitem
|
|
ld a, [hl]
|
|
and a
|
|
ret nz
|
|
|
|
; The player must have an item to steal.
|
|
|
|
call .playeritem
|
|
ld a, [hl]
|
|
and a
|
|
ret z
|
|
|
|
; Can't steal mail!
|
|
|
|
ld [wd265], a
|
|
ld d, a
|
|
farcall ItemIsMail
|
|
ret c
|
|
|
|
ld a, [wEffectFailed]
|
|
and a
|
|
ret nz
|
|
|
|
; If the enemy steals your item,
|
|
; it's gone for good if you don't get it back.
|
|
|
|
call .playeritem
|
|
xor a
|
|
ld [hl], a
|
|
ld [de], a
|
|
|
|
call .enemyitem
|
|
ld a, [wd265]
|
|
ld [hl], a
|
|
ld [de], a
|
|
|
|
|
|
.stole
|
|
call GetItemName
|
|
ld hl, StoleText
|
|
jp StdBattleTextBox
|
|
|
|
|
|
.playeritem
|
|
ld a, 1
|
|
call BattlePartyAttr
|
|
ld d, h
|
|
ld e, l
|
|
ld hl, wBattleMonItem
|
|
ret
|
|
|
|
.enemyitem
|
|
ld a, 1
|
|
call OTPartyAttr
|
|
ld d, h
|
|
ld e, l
|
|
ld hl, wEnemyMonItem
|
|
ret
|
|
; 37517
|