mirror of
https://gitlab.com/xCrystal/pokecrystal-board.git
synced 2024-09-09 09:51:34 -07:00
32ed487a47
# Conflicts: # audio/engine.asm # constants/gfx_constants.asm # constants/map_data_constants.asm # constants/pokemon_data_constants.asm # constants/sprite_constants.asm # constants/wram_constants.asm # data/maps/data.asm # engine/battle/ai/scoring.asm # engine/battle/core.asm # engine/battle/effect_commands.asm # engine/battle/misc.asm # engine/battle_anims/getpokeballwobble.asm # engine/breeding.asm # engine/buy_sell_toss.asm # engine/decorations.asm # engine/events/battle_tower/battle_tower.asm # engine/events/battle_tower/rules.asm # engine/events/buena.asm # engine/events/bug_contest/contest_2.asm # engine/events/daycare.asm # engine/events/dratini.asm # engine/events/halloffame.asm # engine/events/happiness_egg.asm # engine/events/kurt.asm # engine/events/lucky_number.asm # engine/events/magnet_train.asm # engine/events/overworld.asm # engine/events/pokerus/pokerus.asm # engine/events/print_unown.asm # engine/events/print_unown_2.asm # engine/events/unown_walls.asm # engine/item_effects.asm # engine/link.asm # engine/mon_menu.asm # engine/player_object.asm # engine/routines/playslowcry.asm # engine/scripting.asm # engine/search.asm # engine/search2.asm # engine/specials.asm # engine/start_menu.asm # engine/timeset.asm # home/battle_vars.asm # home/map.asm # maps/GoldenrodUndergroundSwitchRoomEntrances.asm # maps/IlexForest.asm # maps/KrissHouse2F.asm # maps/Route39Barn.asm # mobile/mobile_12_2.asm # mobile/mobile_40.asm # mobile/mobile_5f.asm # wram.asm
98 lines
1.5 KiB
NASM
98 lines
1.5 KiB
NASM
BattleCommand_Curse: ; 37588
|
|
; curse
|
|
|
|
ld de, wBattleMonType1
|
|
ld bc, wPlayerStatLevels
|
|
ld a, [hBattleTurn]
|
|
and a
|
|
jr z, .go
|
|
ld de, wEnemyMonType1
|
|
ld bc, wEnemyStatLevels
|
|
|
|
.go
|
|
|
|
; Curse is different for Ghost-types.
|
|
|
|
ld a, [de]
|
|
cp GHOST
|
|
jr z, .ghost
|
|
inc de
|
|
ld a, [de]
|
|
cp GHOST
|
|
jr z, .ghost
|
|
|
|
|
|
; If no stats can be increased, don't.
|
|
|
|
; Attack
|
|
ld a, [bc]
|
|
cp MAX_STAT_LEVEL
|
|
jr c, .raise
|
|
|
|
; Defense
|
|
inc bc
|
|
ld a, [bc]
|
|
cp MAX_STAT_LEVEL
|
|
jr nc, .cantraise
|
|
|
|
.raise
|
|
|
|
; Raise Attack and Defense, and lower Speed.
|
|
|
|
ld a, $1
|
|
ld [wKickCounter], a
|
|
call AnimateCurrentMove
|
|
ld a, SPEED
|
|
call LowerStat
|
|
call BattleCommand_SwitchTurn
|
|
call BattleCommand_StatDownMessage
|
|
call ResetMiss
|
|
call BattleCommand_SwitchTurn
|
|
call BattleCommand_AttackUp
|
|
call BattleCommand_StatUpMessage
|
|
call ResetMiss
|
|
call BattleCommand_DefenseUp
|
|
jp BattleCommand_StatUpMessage
|
|
|
|
|
|
.ghost
|
|
|
|
; Cut HP in half and put a curse on the opponent.
|
|
|
|
call CheckHiddenOpponent
|
|
jr nz, .failed
|
|
|
|
call CheckSubstituteOpp
|
|
jr nz, .failed
|
|
|
|
ld a, BATTLE_VARS_SUBSTATUS1_OPP
|
|
call GetBattleVarAddr
|
|
bit SUBSTATUS_CURSE, [hl]
|
|
jr nz, .failed
|
|
|
|
set SUBSTATUS_CURSE, [hl]
|
|
call AnimateCurrentMove
|
|
ld hl, GetHalfMaxHP
|
|
call CallBattleCore
|
|
ld hl, SubtractHPFromUser
|
|
call CallBattleCore
|
|
call UpdateUserInParty
|
|
ld hl, PutACurseText
|
|
jp StdBattleTextBox
|
|
|
|
.failed
|
|
call AnimateFailedMove
|
|
jp PrintButItFailed
|
|
|
|
|
|
.cantraise
|
|
|
|
; Can't raise either stat.
|
|
|
|
ld b, ABILITY + 1
|
|
call GetStatName
|
|
call AnimateFailedMove
|
|
ld hl, WontRiseAnymoreText
|
|
jp StdBattleTextBox
|
|
; 37618
|