mirror of
https://gitlab.com/xCrystal/pokecrystal-board.git
synced 2024-09-09 09:51:34 -07:00
32ed487a47
# Conflicts: # audio/engine.asm # constants/gfx_constants.asm # constants/map_data_constants.asm # constants/pokemon_data_constants.asm # constants/sprite_constants.asm # constants/wram_constants.asm # data/maps/data.asm # engine/battle/ai/scoring.asm # engine/battle/core.asm # engine/battle/effect_commands.asm # engine/battle/misc.asm # engine/battle_anims/getpokeballwobble.asm # engine/breeding.asm # engine/buy_sell_toss.asm # engine/decorations.asm # engine/events/battle_tower/battle_tower.asm # engine/events/battle_tower/rules.asm # engine/events/buena.asm # engine/events/bug_contest/contest_2.asm # engine/events/daycare.asm # engine/events/dratini.asm # engine/events/halloffame.asm # engine/events/happiness_egg.asm # engine/events/kurt.asm # engine/events/lucky_number.asm # engine/events/magnet_train.asm # engine/events/overworld.asm # engine/events/pokerus/pokerus.asm # engine/events/print_unown.asm # engine/events/print_unown_2.asm # engine/events/unown_walls.asm # engine/item_effects.asm # engine/link.asm # engine/mon_menu.asm # engine/player_object.asm # engine/routines/playslowcry.asm # engine/scripting.asm # engine/search.asm # engine/search2.asm # engine/specials.asm # engine/start_menu.asm # engine/timeset.asm # home/battle_vars.asm # home/map.asm # maps/GoldenrodUndergroundSwitchRoomEntrances.asm # maps/IlexForest.asm # maps/KrissHouse2F.asm # maps/Route39Barn.asm # mobile/mobile_12_2.asm # mobile/mobile_40.asm # mobile/mobile_5f.asm # wram.asm
142 lines
2.4 KiB
NASM
Executable File
142 lines
2.4 KiB
NASM
Executable File
|
|
BattleCommand_Transform: ; 371cd
|
|
; transform
|
|
|
|
call ClearLastMove
|
|
ld a, BATTLE_VARS_SUBSTATUS5_OPP
|
|
call GetBattleVarAddr
|
|
bit SUBSTATUS_TRANSFORMED, [hl]
|
|
jp nz, BattleEffect_ButItFailed
|
|
call CheckHiddenOpponent
|
|
jp nz, BattleEffect_ButItFailed
|
|
xor a
|
|
ld [wNumHits], a
|
|
ld [wFXAnimID + 1], a
|
|
ld a, $1
|
|
ld [wKickCounter], a
|
|
ld a, BATTLE_VARS_SUBSTATUS4
|
|
call GetBattleVarAddr
|
|
bit SUBSTATUS_SUBSTITUTE, [hl]
|
|
push af
|
|
jr z, .mimic_substitute
|
|
call CheckUserIsCharging
|
|
jr nz, .mimic_substitute
|
|
ld a, SUBSTITUTE
|
|
call LoadAnim
|
|
.mimic_substitute
|
|
ld a, BATTLE_VARS_SUBSTATUS5
|
|
call GetBattleVarAddr
|
|
set SUBSTATUS_TRANSFORMED, [hl]
|
|
call ResetActorDisable
|
|
ld hl, wBattleMonSpecies
|
|
ld de, wEnemyMonSpecies
|
|
ld a, [hBattleTurn]
|
|
and a
|
|
jr nz, .got_mon_species
|
|
ld hl, wEnemyMonSpecies
|
|
ld de, wBattleMonSpecies
|
|
xor a
|
|
ld [wCurMoveNum], a
|
|
.got_mon_species
|
|
push hl
|
|
ld a, [hli]
|
|
ld [de], a
|
|
inc hl
|
|
inc de
|
|
inc de
|
|
ld bc, NUM_MOVES
|
|
call CopyBytes
|
|
ld a, [hBattleTurn]
|
|
and a
|
|
jr z, .mimic_enemy_backup
|
|
ld a, [de]
|
|
ld [wEnemyBackupDVs], a
|
|
inc de
|
|
ld a, [de]
|
|
ld [wEnemyBackupDVs + 1], a
|
|
dec de
|
|
.mimic_enemy_backup
|
|
; copy DVs
|
|
ld a, [hli]
|
|
ld [de], a
|
|
inc de
|
|
ld a, [hli]
|
|
ld [de], a
|
|
inc de
|
|
; move pointer to stats
|
|
ld bc, wBattleMonStats - wBattleMonPP
|
|
add hl, bc
|
|
push hl
|
|
ld h, d
|
|
ld l, e
|
|
add hl, bc
|
|
ld d, h
|
|
ld e, l
|
|
pop hl
|
|
ld bc, wBattleMonStructEnd - wBattleMonStats
|
|
call CopyBytes
|
|
; init the power points
|
|
ld bc, wBattleMonMoves - wBattleMonStructEnd
|
|
add hl, bc
|
|
push de
|
|
ld d, h
|
|
ld e, l
|
|
pop hl
|
|
ld bc, wBattleMonPP - wBattleMonStructEnd
|
|
add hl, bc
|
|
ld b, NUM_MOVES
|
|
.pp_loop
|
|
ld a, [de]
|
|
inc de
|
|
and a
|
|
jr z, .done_move
|
|
cp SKETCH
|
|
ld a, 1
|
|
jr z, .done_move
|
|
ld a, 5
|
|
.done_move
|
|
ld [hli], a
|
|
dec b
|
|
jr nz, .pp_loop
|
|
pop hl
|
|
ld a, [hl]
|
|
ld [wNamedObjectIndexBuffer], a
|
|
call GetPokemonName
|
|
ld hl, wEnemyStats
|
|
ld de, wPlayerStats
|
|
ld bc, 2 * 5
|
|
call BattleSideCopy
|
|
ld hl, wEnemyStatLevels
|
|
ld de, wPlayerStatLevels
|
|
ld bc, 8
|
|
call BattleSideCopy
|
|
call _CheckBattleScene
|
|
jr c, .mimic_anims
|
|
ld a, [hBattleTurn]
|
|
and a
|
|
ld a, [wPlayerMinimized]
|
|
jr z, .got_byte
|
|
ld a, [wEnemyMinimized]
|
|
.got_byte
|
|
and a
|
|
jr nz, .mimic_anims
|
|
call LoadMoveAnim
|
|
jr .after_anim
|
|
|
|
.mimic_anims
|
|
call BattleCommand_MoveDelay
|
|
call BattleCommand_RaiseSubNoAnim
|
|
.after_anim
|
|
xor a
|
|
ld [wNumHits], a
|
|
ld [wFXAnimID + 1], a
|
|
ld a, $2
|
|
ld [wKickCounter], a
|
|
pop af
|
|
ld a, SUBSTITUTE
|
|
call nz, LoadAnim
|
|
ld hl, TransformedText
|
|
jp StdBattleTextBox
|
|
|
|
; 372c6
|