mirror of
https://gitlab.com/xCrystal/pokecrystal-board.git
synced 2024-09-09 09:51:34 -07:00
32ed487a47
# Conflicts: # audio/engine.asm # constants/gfx_constants.asm # constants/map_data_constants.asm # constants/pokemon_data_constants.asm # constants/sprite_constants.asm # constants/wram_constants.asm # data/maps/data.asm # engine/battle/ai/scoring.asm # engine/battle/core.asm # engine/battle/effect_commands.asm # engine/battle/misc.asm # engine/battle_anims/getpokeballwobble.asm # engine/breeding.asm # engine/buy_sell_toss.asm # engine/decorations.asm # engine/events/battle_tower/battle_tower.asm # engine/events/battle_tower/rules.asm # engine/events/buena.asm # engine/events/bug_contest/contest_2.asm # engine/events/daycare.asm # engine/events/dratini.asm # engine/events/halloffame.asm # engine/events/happiness_egg.asm # engine/events/kurt.asm # engine/events/lucky_number.asm # engine/events/magnet_train.asm # engine/events/overworld.asm # engine/events/pokerus/pokerus.asm # engine/events/print_unown.asm # engine/events/print_unown_2.asm # engine/events/unown_walls.asm # engine/item_effects.asm # engine/link.asm # engine/mon_menu.asm # engine/player_object.asm # engine/routines/playslowcry.asm # engine/scripting.asm # engine/search.asm # engine/search2.asm # engine/specials.asm # engine/start_menu.asm # engine/timeset.asm # home/battle_vars.asm # home/map.asm # maps/GoldenrodUndergroundSwitchRoomEntrances.asm # maps/IlexForest.asm # maps/KrissHouse2F.asm # maps/Route39Barn.asm # mobile/mobile_12_2.asm # mobile/mobile_40.asm # mobile/mobile_5f.asm # wram.asm
132 lines
1.5 KiB
NASM
132 lines
1.5 KiB
NASM
ResetGameTime:: ; 208a
|
|
xor a
|
|
ld [wGameTimeCap], a
|
|
ld [wGameTimeHours], a
|
|
ld [wGameTimeHours + 1], a
|
|
ld [wGameTimeMinutes], a
|
|
ld [wGameTimeSeconds], a
|
|
ld [wGameTimeFrames], a
|
|
ret
|
|
; 209e
|
|
|
|
|
|
GameTimer:: ; 209e
|
|
|
|
nop
|
|
|
|
ld a, [rSVBK]
|
|
push af
|
|
ld a, BANK(wGameTime)
|
|
ld [rSVBK], a
|
|
|
|
call UpdateGameTimer
|
|
|
|
pop af
|
|
ld [rSVBK], a
|
|
ret
|
|
; 20ad
|
|
|
|
|
|
UpdateGameTimer:: ; 20ad
|
|
; Increment the game timer by one frame.
|
|
; The game timer is capped at 999:59:59.00.
|
|
|
|
|
|
; Don't update if game logic is paused.
|
|
ld a, [wGameLogicPaused]
|
|
and a
|
|
ret nz
|
|
|
|
; Is the timer paused?
|
|
ld hl, wGameTimerPause
|
|
bit GAMETIMERPAUSE_TIMER_PAUSED_F, [hl]
|
|
ret z
|
|
|
|
; Is the timer already capped?
|
|
ld hl, wGameTimeCap
|
|
bit 0, [hl]
|
|
ret nz
|
|
|
|
|
|
; +1 frame
|
|
ld hl, wGameTimeFrames
|
|
ld a, [hl]
|
|
inc a
|
|
|
|
cp 60 ; frames/second
|
|
jr nc, .second
|
|
|
|
ld [hl], a
|
|
ret
|
|
|
|
|
|
.second
|
|
xor a
|
|
ld [hl], a
|
|
|
|
; +1 second
|
|
ld hl, wGameTimeSeconds
|
|
ld a, [hl]
|
|
inc a
|
|
|
|
cp 60 ; seconds/minute
|
|
jr nc, .minute
|
|
|
|
ld [hl], a
|
|
ret
|
|
|
|
|
|
.minute
|
|
xor a
|
|
ld [hl], a
|
|
|
|
; +1 minute
|
|
ld hl, wGameTimeMinutes
|
|
ld a, [hl]
|
|
inc a
|
|
|
|
cp 60 ; minutes/hour
|
|
jr nc, .hour
|
|
|
|
ld [hl], a
|
|
ret
|
|
|
|
|
|
.hour
|
|
xor a
|
|
ld [hl], a
|
|
|
|
; +1 hour
|
|
ld a, [wGameTimeHours]
|
|
ld h, a
|
|
ld a, [wGameTimeHours + 1]
|
|
ld l, a
|
|
inc hl
|
|
|
|
|
|
; Cap the timer after 1000 hours.
|
|
ld a, h
|
|
cp HIGH(1000)
|
|
jr c, .ok
|
|
|
|
ld a, l
|
|
cp LOW(1000)
|
|
jr c, .ok
|
|
|
|
ld hl, wGameTimeCap
|
|
set 0, [hl]
|
|
|
|
ld a, 59 ; 999:59:59.00
|
|
ld [wGameTimeMinutes], a
|
|
ld [wGameTimeSeconds], a
|
|
ret
|
|
|
|
|
|
.ok
|
|
ld a, h
|
|
ld [wGameTimeHours], a
|
|
ld a, l
|
|
ld [wGameTimeHours + 1], a
|
|
ret
|
|
; 210f
|