vkd3d/tests/hlsl/conditional.shader_test

[pixel shader]
uniform float4 u;

float4 main() : sv_target
{
    if (u.x > 0.0)
        return float4(0.1, 0.2, 0.3, 0.4);
    else
        return float4(0.9, 0.8, 0.7, 0.6);
}

[test]
uniform 0 float4 0.0 0.0 0.0 0.0
draw quad
probe (0, 0) f32(0.9, 0.8, 0.7, 0.6)
uniform 0 float4 0.1 0.0 0.0 0.0
draw quad
probe (0, 0) f32(0.1, 0.2, 0.3, 0.4)

[pixel shader]
uniform float4 u;

float4 main() : sv_target
{
    [attr1]
    if (u.x > 0.0)
        return float4(0.1, 0.2, 0.3, 0.4);
    else
        return float4(0.9, 0.8, 0.7, 0.6);
}

[pixel shader]
uniform float4 u;

float4 main() : sv_target
{
    [flatten]
    if (u.x > 0.0)
        return float4(0.1, 0.2, 0.3, 0.4);
    else
        return float4(0.9, 0.8, 0.7, 0.6);
}

[test]
uniform 0 float4 0.0 0.0 0.0 0.0
draw quad
probe (0, 0) f32(0.9, 0.8, 0.7, 0.6)

[pixel shader fail(sm<6)]
float4 u;

float main() : sv_target
{
    [branch] [branch]
    if (u.x > 0.0)
        return float4(0.1, 0.2, 0.3, 0.4);
    else
        return float4(0.9, 0.8, 0.7, 0.6);
}

[pixel shader fail]
float4 u;

float main() : sv_target
{
    [branch] [flatten]
    if (u.x > 0.0)
        return float4(0.1, 0.2, 0.3, 0.4);
    else
        return float4(0.9, 0.8, 0.7, 0.6);
}

[vertex shader]
void main(float4 p : position, out float t[4] : texcoord, out float4 position : sv_position)
{
    t[0] = (p.x + 1.0) / 2.0;
    t[2] = 0.0;
    t[1] = (p.y + 1.0) / 2.0;
    t[3] = 1.0;
    position = p;
}

[pixel shader]
float4 main(float t[4] : texcoord) : sv_target
{
    if (t[0] > 0.5)
        return floor(float4(t) * 128.0 + 0.5) / 128.0;
    return float4(0.0, 1.0, 0.0, 1.0);
}

[test]
todo(msl & sm>=6) draw quad
probe (160, 120) f32(0.00, 1.00, 0.0, 1.0)
probe (480, 120) f32(0.75, 0.75, 0.0, 1.0)
probe (160, 360) f32(0.00, 1.00, 0.0, 1.0)
probe (480, 360) f32(0.75, 0.25, 0.0, 1.0)

% Using older profiles fails to compile with forced control flow instruction
[require]
shader model >= 3.0

[vertex shader]
float4 main(float4 p : position) : sv_position
{
    return p;
}

[pixel shader]
uniform float a;

float4 main() : sv_target
{
    if (a < 4)
        return float4(1, 2, 3, 4);
    return float4(10, 20, 30, 40);
}

[test]
uniform 0 float -2
draw quad
probe (0, 0) rgba (1, 2, 3, 4)
uniform 0 float 10
draw quad
probe (0, 0) rgba (10, 20, 30, 40)

[pixel shader]
uniform float4 u;

float4 main() : sv_target
{
    [branch]
    if (u.x > 0.0)
        return float4(0.1, 0.2, 0.3, 0.4);
    else
        return float4(0.9, 0.8, 0.7, 0.6);
}

[test]
uniform 0 float4 0.0 0.0 0.0 0.0
draw quad
probe (0, 0) rgba (0.9, 0.8, 0.7, 0.6)

[pixel shader]
uniform float4 u;

float4 main() : sv_target
{
    [flatten]
    if (u.x > 0.0)
    {
        [branch]
        if (u.y > 0.0)
            return float4(1.0, 2.0, 3.0, 4.0);
        else
            return float4(5.0, 6.0, 7.0, 8.0);
    }
    else
        return float4(9.0, 10.0, 11.0, 12.0);
}

[test]
uniform 0 float4 1.0 0.0 0.0 0.0
draw quad
probe (0, 0) f32(5.0, 6.0, 7.0, 8.0)
uniform 0 float4 1.0 1.0 0.0 0.0
draw quad
probe (0, 0) f32(1.0, 2.0, 3.0, 4.0)
uniform 0 float4 0.0 1.0 0.0 0.0
draw quad
probe (0, 0) f32(9.0, 10.0, 11.0, 12.0)

[pixel shader]
float4 main() : sv_target
{
    bool c = false;
    float a = -1.0f;
    if (c)
        return float4(1.0, 2.0, 3.0, 4.0);
    else if (a > 0)
        return float4(5.0, 6.0, 7.0, 8.0);
    else
        return float4(9.0, 10.0, 11.0, 12.0);
}

[test]
draw quad
probe (0, 0) rgba (9.0, 10.0, 11.0, 12.0)


[pixel shader]
int a, b;

float4 main() : sv_target
{
    if (a < b)
        return -1.0;
    else
        return 1.0;
}

[test]
if(sm<4)  uniform 0 float 8
if(sm<4)  uniform 4 float 9
if(sm>=4) uniform 0 int 8
if(sm>=4) uniform 1 int 9
draw quad
probe (0, 0) rgba (-1.0, -1.0, -1.0, -1.0)
if(sm<4)  uniform 0 float -3
if(sm<4)  uniform 4 float -4
if(sm>=4) uniform 0 int -3
if(sm>=4) uniform 1 int -4
draw quad
probe (0, 0) rgba (1.0, 1.0, 1.0, 1.0)
if(sm<4)  uniform 0 float 7
if(sm<4)  uniform 4 float 7
if(sm>=4) uniform 0 int 7
if(sm>=4) uniform 1 int 7
draw quad
probe (0, 0) rgba (1.0, 1.0, 1.0, 1.0)

[pixel shader]
int a, b;

float4 main() : sv_target
{
    if (a <= b)
        return -1.0;
    else
        return 1.0;
}

[test]
if(sm<4)  uniform 0 float 8
if(sm<4)  uniform 4 float 9
if(sm>=4) uniform 0 int 8
if(sm>=4) uniform 1 int 9
draw quad
probe (0, 0) rgba (-1.0, -1.0, -1.0, -1.0)
if(sm<4)  uniform 0 float -3
if(sm<4)  uniform 4 float -4
if(sm>=4) uniform 0 int -3
if(sm>=4) uniform 1 int -4
draw quad
probe (0, 0) rgba (1.0, 1.0, 1.0, 1.0)
if(sm<4)  uniform 0 float 7
if(sm<4)  uniform 4 float 7
if(sm>=4) uniform 0 int 7
if(sm>=4) uniform 1 int 7
draw quad
probe (0, 0) rgba (-1.0, -1.0, -1.0, -1.0)

[pixel shader]
int a, b;

float4 main() : sv_target
{
    if (a != b)
        return -1.0;
    else
        return 1.0;
}

[test]
if(sm<4)  uniform 0 float -3
if(sm<4)  uniform 4 float -2
if(sm>=4) uniform 0 int -3
if(sm>=4) uniform 1 int -2
draw quad
probe (0, 0) rgba (-1.0, -1.0, -1.0, -1.0)
if(sm<4)  uniform 0 float 4
if(sm<4)  uniform 4 float 4
if(sm>=4) uniform 0 int 4
if(sm>=4) uniform 1 int 4
draw quad
probe (0, 0) rgba (1.0, 1.0, 1.0, 1.0)

[pixel shader]
uniform float4 u;

float4 main() : sv_target
{
    float res = 0;

    [flatten]
    if (u.x > 0.0)
        res = 1.0;
    else
        res = 2.0;

    return res;
}

[test]
uniform 0 float4 0.0 0.0 0.0 0.0
draw quad
probe (0, 0) f32(2.0, 2.0, 2.0, 2.0)
uniform 0 float4 1.0 0.0 0.0 0.0
draw quad
probe (0, 0) f32(1.0, 1.0, 1.0, 1.0)

[pixel shader]
uniform float4 u;

float4 main() : sv_target
{
    float4 res = float4(0.0, -1.0, -2.0, -3.0);

    [flatten]
    if (u.x > 0.0)
        res.xy = float2(4.0, 5.0);
    else
        res.xz = float2(6.0, 7.0);

    return res;
}

[test]
uniform 0 float4 0.0 0.0 0.0 0.0
draw quad
probe (0, 0) f32(6.0, -1.0, 7.0, -3.0)
uniform 0 float4 1.0 0.0 0.0 0.0
draw quad
probe (0, 0) f32(4.0, 5.0, -2.0, -3.0)

% Test "if" conditionals, using resource loads to ensure we aren't removing these instruction with optimizations.
[srv 0]
size (2d, 2, 2)
0.0 0.0 0.0 4.0     1.0 0.0 0.0 4.0
0.0 1.0 0.0 4.0     1.0 1.0 0.0 4.0

[sampler 0]
filter linear linear linear
address clamp clamp clamp

[pixel shader]
Texture2D tex;
sampler sam;
float a;

float4 main() : sv_target
{
    if (a < 4)
        return tex.Sample(sam, float2(0, 0));
    return float4(1, 2, 3, 4);
}

[test]
uniform 0 float -2
draw quad
probe (0, 0) rgba (0.0, 0.0, 0.0, 4.0)
uniform 0 float 4
draw quad
probe (0, 0) rgba (1.0, 2.0, 3.0, 4.0)

[pixel shader]
Texture2D tex;
sampler sam;
float a;

float4 main() : sv_target
{
    [flatten] if (a < 4)
        return tex.Sample(sam, float2(0, 0));
    else
        return float4(1, 2, 3, 4);
}

[test]
uniform 0 float -2
draw quad
probe (0, 0) f32(0.0, 0.0, 0.0, 4.0)
uniform 0 float 4
draw quad
probe (0, 0) f32(1.0, 2.0, 3.0, 4.0)

[pixel shader]
Texture2D tex;
sampler sam;
float a;

float4 main() : sv_target
{
    if (a >= 2)
        return tex.Sample(sam, float2(0, 0));
    else if (a >= 1)
        return tex.Sample(sam, float2(1, 0));
    else
        return tex.Sample(sam, float2(1, 1));
}

[test]
uniform 0 float 2
todo(msl & sm>=6) draw quad
probe (0, 0) rgba (0.0, 0.0, 0.0, 4.0)
uniform 0 float 1
todo(msl & sm>=6) draw quad
probe (0, 0) rgba (1.0, 0.0, 0.0, 4.0)
uniform 0 float 0
todo(msl & sm>=6) draw quad
probe (0, 0) rgba (1.0, 1.0, 0.0, 4.0)

% Branches with resource stores can't be flattened.
[pixel shader fail(sm<6)]
uniform float a;
RWBuffer<float> u;

float4 main() : sv_target
{
    [flatten]
    if (a > 0)
       u[0] = a;
    return a;
}

[pixel shader fail(sm<6) todo]
uniform float a;
uniform uint b;
RWBuffer<float> u;

float4 main() : sv_target
{
    [flatten]
    if (a > 0)
    {
       for (uint i = 0; i < b; ++i)
       {
           if (i > 3)
               u[i] = a + i;
       }
    }
    return a;
}

% Test 16-bit phi instructions.
[require]
shader model >= 6.2
native-16-bit

[pixel shader]
Texture2D<half4> tex;
float a;

half4 main() : sv_target
{
    if (a >= 2)
        return tex.Load(int3(0, 0, 0));
    else
        return half(a);
}

[test]
uniform 0 float 2
draw quad
probe (0, 0) rgba(0.0, 0.0, 0.0, 4.0)
uniform 0 float 1
draw quad
probe (0, 0) rgba(1.0, 1.0, 1.0, 1.0)