mirror of
https://gitlab.com/xCrystal/pokecrystal-board.git
synced 2024-09-09 09:51:34 -07:00
43eff93861
Time to move everything out of home.asm: - InexplicablyEmptyFunction was moved to home/map.asm - The wDebugFlags functions and xor_a brothers were moved to home/flag.asm because they're all flag-related. - ret_2f3e was moved into home/region.asm - The register alias sisters were moved to a new file called home/call_regs.asm - IsInArray and SkipNames were joined by AddNTimes from home/math.asm into home/array.asm, as they're all used to index arrays. - CallPointerAt was moved into home/print_text.asm because given the contents of that file it doesn't feel very out of place (that file isn't very aptly named...) - CountSetBits was moved into home/pokedex_flags.asm because it's unique use is counting the amount of seen/caught mon in the podedex. GetWeekday was pulled into this by proximity. Other changes were also made: - PushLYOverrides was moved from home/sprite_anims.asm to home/battle.asm, because it's almost exclusively used for battle animations, with the lone exception being the Magnet Train. - home/copy.asm was renamed to home/gfx.asm, as it's all gfx-related - home/copy2.asm was renamed to home/copy.asm, now it's the only file called copy. - SetHPPal and GetHPPal were moved from home/hp_pals.asm to home/tilemap.asm, as they're attrmap related, like many functions in that file are. - home/rtc.asm was renamed to home/time_palettes.asm, as it had very little to do with the RTC at all, all RTC functions being in home/time.asm - home/handshake.asm was renamed to home/printer.asm. - home/mon_data_2.asm was renamed to home/mon_party.asm.
131 lines
1.6 KiB
NASM
131 lines
1.6 KiB
NASM
ResetMapBufferEventFlags::
|
|
xor a
|
|
ld hl, wEventFlags
|
|
ld [hli], a
|
|
ret
|
|
|
|
ResetBikeFlags::
|
|
xor a
|
|
ld hl, wBikeFlags
|
|
ld [hli], a
|
|
ld [hl], a
|
|
ret
|
|
|
|
ResetFlashIfOutOfCave::
|
|
ld a, [wEnvironment]
|
|
cp ROUTE
|
|
jr z, .outdoors
|
|
cp TOWN
|
|
jr z, .outdoors
|
|
ret
|
|
|
|
.outdoors
|
|
ld hl, wStatusFlags
|
|
res STATUSFLAGS_FLASH_F, [hl]
|
|
ret
|
|
|
|
EventFlagAction::
|
|
ld hl, wEventFlags
|
|
call FlagAction
|
|
ret
|
|
|
|
FlagAction::
|
|
; Perform action b on bit de in flag array hl.
|
|
|
|
; inputs:
|
|
; b: function
|
|
; 0 RESET_FLAG clear bit
|
|
; 1 SET_FLAG set bit
|
|
; 2 CHECK_FLAG check bit
|
|
; de: bit number
|
|
; hl: pointer to the flag array
|
|
|
|
; get index within the byte
|
|
ld a, e
|
|
and 7
|
|
|
|
; shift de right by three bits (get the index within memory)
|
|
rept 3
|
|
srl d
|
|
rr e
|
|
endr
|
|
add hl, de
|
|
|
|
; implement a decoder
|
|
ld c, 1
|
|
rrca
|
|
jr nc, .one
|
|
rlc c
|
|
.one
|
|
rrca
|
|
jr nc, .two
|
|
rlc c
|
|
rlc c
|
|
.two
|
|
rrca
|
|
jr nc, .three
|
|
swap c
|
|
.three
|
|
|
|
; check b's value: 0, 1, 2
|
|
ld a, b
|
|
cp SET_FLAG
|
|
jr c, .clearbit ; RESET_FLAG
|
|
jr z, .setbit ; SET_FLAG
|
|
|
|
; check bit
|
|
ld a, [hl]
|
|
and c
|
|
ld c, a
|
|
ret
|
|
|
|
.setbit
|
|
; set bit
|
|
ld a, [hl]
|
|
or c
|
|
ld [hl], a
|
|
ret
|
|
|
|
.clearbit
|
|
; clear bit
|
|
ld a, c
|
|
cpl
|
|
and [hl]
|
|
ld [hl], a
|
|
ret
|
|
|
|
CheckReceivedDex::
|
|
ld de, ENGINE_POKEDEX
|
|
ld b, CHECK_FLAG
|
|
farcall EngineFlagAction
|
|
ld a, c
|
|
and a
|
|
ret
|
|
|
|
Unreferenced_CheckBPressedDebug::
|
|
; Used in debug ROMs to walk through walls and avoid encounters.
|
|
|
|
ld a, [wDebugFlags]
|
|
bit DEBUG_FIELD_F, a
|
|
ret z
|
|
|
|
ldh a, [hJoyDown]
|
|
bit B_BUTTON_F, a
|
|
ret
|
|
|
|
xor_a::
|
|
xor a
|
|
ret
|
|
|
|
xor_a_dec_a::
|
|
xor a
|
|
dec a
|
|
ret
|
|
|
|
Unreferenced_CheckFieldDebug::
|
|
push hl
|
|
ld hl, wDebugFlags
|
|
bit DEBUG_FIELD_F, [hl]
|
|
pop hl
|
|
ret
|