mirror of
https://gitlab.com/xCrystal/pokecrystal-board.git
synced 2024-09-09 09:51:34 -07:00
43eff93861
Time to move everything out of home.asm: - InexplicablyEmptyFunction was moved to home/map.asm - The wDebugFlags functions and xor_a brothers were moved to home/flag.asm because they're all flag-related. - ret_2f3e was moved into home/region.asm - The register alias sisters were moved to a new file called home/call_regs.asm - IsInArray and SkipNames were joined by AddNTimes from home/math.asm into home/array.asm, as they're all used to index arrays. - CallPointerAt was moved into home/print_text.asm because given the contents of that file it doesn't feel very out of place (that file isn't very aptly named...) - CountSetBits was moved into home/pokedex_flags.asm because it's unique use is counting the amount of seen/caught mon in the podedex. GetWeekday was pulled into this by proximity. Other changes were also made: - PushLYOverrides was moved from home/sprite_anims.asm to home/battle.asm, because it's almost exclusively used for battle animations, with the lone exception being the Magnet Train. - home/copy.asm was renamed to home/gfx.asm, as it's all gfx-related - home/copy2.asm was renamed to home/copy.asm, now it's the only file called copy. - SetHPPal and GetHPPal were moved from home/hp_pals.asm to home/tilemap.asm, as they're attrmap related, like many functions in that file are. - home/rtc.asm was renamed to home/time_palettes.asm, as it had very little to do with the RTC at all, all RTC functions being in home/time.asm - home/handshake.asm was renamed to home/printer.asm. - home/mon_data_2.asm was renamed to home/mon_party.asm.
132 lines
2.0 KiB
NASM
132 lines
2.0 KiB
NASM
CopyBytes::
|
|
; copy bc bytes from hl to de
|
|
inc b ; we bail the moment b hits 0, so include the last run
|
|
inc c ; same thing; include last byte
|
|
jr .HandleLoop
|
|
.CopyByte:
|
|
ld a, [hli]
|
|
ld [de], a
|
|
inc de
|
|
.HandleLoop:
|
|
dec c
|
|
jr nz, .CopyByte
|
|
dec b
|
|
jr nz, .CopyByte
|
|
ret
|
|
|
|
SwapBytes::
|
|
; swap bc bytes between hl and de
|
|
.Loop:
|
|
; stash [hl] away on the stack
|
|
ld a, [hl]
|
|
push af
|
|
|
|
; copy a byte from [de] to [hl]
|
|
ld a, [de]
|
|
ld [hli], a
|
|
|
|
; retrieve the previous value of [hl]; put it in [de]
|
|
pop af
|
|
ld [de], a
|
|
inc de
|
|
|
|
; handle loop stuff
|
|
dec bc
|
|
ld a, b
|
|
or c
|
|
jr nz, .Loop
|
|
ret
|
|
|
|
ByteFill::
|
|
; fill bc bytes with the value of a, starting at hl
|
|
inc b ; we bail the moment b hits 0, so include the last run
|
|
inc c ; same thing; include last byte
|
|
jr .HandleLoop
|
|
.PutByte:
|
|
ld [hli], a
|
|
.HandleLoop:
|
|
dec c
|
|
jr nz, .PutByte
|
|
dec b
|
|
jr nz, .PutByte
|
|
ret
|
|
|
|
GetFarByte::
|
|
; retrieve a single byte from a:hl, and return it in a.
|
|
; bankswitch to new bank
|
|
ldh [hBuffer], a
|
|
ldh a, [hROMBank]
|
|
push af
|
|
ldh a, [hBuffer]
|
|
rst Bankswitch
|
|
|
|
; get byte from new bank
|
|
ld a, [hl]
|
|
ldh [hBuffer], a
|
|
|
|
; bankswitch to previous bank
|
|
pop af
|
|
rst Bankswitch
|
|
|
|
; return retrieved value in a
|
|
ldh a, [hBuffer]
|
|
ret
|
|
|
|
GetFarHalfword::
|
|
; retrieve a halfword from a:hl, and return it in hl.
|
|
; bankswitch to new bank
|
|
ldh [hBuffer], a
|
|
ldh a, [hROMBank]
|
|
push af
|
|
ldh a, [hBuffer]
|
|
rst Bankswitch
|
|
|
|
; get halfword from new bank, put it in hl
|
|
ld a, [hli]
|
|
ld h, [hl]
|
|
ld l, a
|
|
|
|
; bankswitch to previous bank and return
|
|
pop af
|
|
rst Bankswitch
|
|
ret
|
|
|
|
FarCopyWRAM::
|
|
ldh [hBuffer], a
|
|
ldh a, [rSVBK]
|
|
push af
|
|
ldh a, [hBuffer]
|
|
ldh [rSVBK], a
|
|
|
|
call CopyBytes
|
|
|
|
pop af
|
|
ldh [rSVBK], a
|
|
ret
|
|
|
|
GetFarWRAMByte::
|
|
ldh [hBuffer], a
|
|
ldh a, [rSVBK]
|
|
push af
|
|
ldh a, [hBuffer]
|
|
ldh [rSVBK], a
|
|
ld a, [hl]
|
|
ldh [hBuffer], a
|
|
pop af
|
|
ldh [rSVBK], a
|
|
ldh a, [hBuffer]
|
|
ret
|
|
|
|
GetFarWRAMWord::
|
|
ldh [hBuffer], a
|
|
ldh a, [rSVBK]
|
|
push af
|
|
ldh a, [hBuffer]
|
|
ldh [rSVBK], a
|
|
ld a, [hli]
|
|
ld h, [hl]
|
|
ld l, a
|
|
pop af
|
|
ldh [rSVBK], a
|
|
ret
|