Imported Upstream version 4.8.0.309

Former-commit-id: 5f9c6ae75f295e057a7d2971f3a6df4656fa8850

external/cecil-legacy/Test/Resources/il/explicitthis.il

@@ -0,0 +1,113 @@
+.assembly extern mscorlib
+{
+  .ver 0:0:0:0
+}
+
+.assembly fptr
+{
+  .ver 0:0:0:0
+}
+.module fptr.exe
+
+.method public static void  Main() cil managed
+{
+	.entrypoint
+	.locals init (class MakeDecision d, method instance explicit int32 *(class MakeDecision, int32) m, int32 i)
+
+	ldc.i4.1
+	ldc.i4 42
+	newobj     instance void MakeDecision::.ctor(bool, int32)
+	stloc d
+
+	ldc.i4.0
+	stloc i
+	br test
+
+loop:
+	ldloc d
+	call       instance method instance explicit int32 *(class MakeDecision, int32) MakeDecision::Decide()
+	stloc m
+
+	ldloc d
+	ldc.i4.1
+	ldloc m
+	calli      instance int32(int32)
+	call       void [mscorlib]System.Console::WriteLine(int32)
+
+	ldloc i
+	ldc.i4.1
+	add
+	stloc i
+
+test:
+	ldloc i
+	ldc.i4 10
+	blt loop
+
+	ret
+}
+
+.class public auto ansi sealed MakeDecision
+       extends [mscorlib]System.Object
+{
+	.field private bool Oscillate
+	.field private int32 Value
+
+	.method public instance method instance explicit int32 *(class MakeDecision, int32) Decide() cil managed
+	{
+		.locals init (bool t)
+
+		ldarg.0
+		ldfld     bool MakeDecision::Oscillate
+		stloc t
+
+		ldarg.0
+		ldloc t
+		ldc.i4.0
+		ceq
+		stfld bool MakeDecision::Oscillate
+
+		ldloc t
+		brfalse subs
+
+		ldftn      instance int32 MakeDecision::Add(int32)
+		ret
+
+	subs:
+		ldftn      instance int32 MakeDecision::Sub(int32)
+		ret
+	}
+
+	.method public int32  Add(int32 i) cil managed
+	{
+		ldarg.0
+		ldfld      int32 MakeDecision::Value
+		ldarg      i
+		add
+		ret
+	}
+
+	.method public int32  Sub(int32 i) cil managed
+	{
+		ldarg.0
+		ldfld      int32 MakeDecision::Value
+		ldarg      i
+		sub
+		ret
+	}
+
+	.method public hidebysig specialname rtspecialname  instance void  .ctor(bool s, int32 val) cil managed
+	{
+		ldarg.0
+		ldarg s
+		stfld      bool MakeDecision::Oscillate
+
+		ldarg.0
+		ldarg val
+		stfld      int32 MakeDecision::Value
+
+		ldarg.0
+		call       instance void [mscorlib]System.Object::.ctor()
+		ret
+	}
+}

external/cecil-legacy/Test/Resources/il/hello.il

@@ -0,0 +1,84 @@
+.assembly extern mscorlib
+{
+  .publickeytoken = (B7 7A 5C 56 19 34 E0 89)
+  .ver 2:0:0:0
+}
+
+.assembly Hello {}
+
+.module Hello.dll
+
+.class private auto ansi Foo {
+
+	.method public specialname rtspecialname instance void .ctor () cil managed
+	{
+		ldarg.0
+		call instance void [mscorlib]System.Object::.ctor ()
+		ret
+	}
+
+	.method public static void Bar (int32 a, int32 b)
+	{
+		.locals init (int32 res)
+		ldarg.0
+		ldarg.1
+		mul
+		stloc.0
+		ldloc.0
+		call void Foo::Baz (int32)
+		ret
+	}
+
+	.method public static void Baz (int32 a)
+	{
+		ret
+	}
+
+	.method public void Gazonk ()
+	{
+		ldarg 0
+		pop
+		ret
+	}
+
+	.method public static void PrintEmpty ()
+	{
+		ldsfld string [mscorlib]System.String::Empty
+		call void [mscorlib]System.Console::WriteLine(string)
+		ret
+	}
+
+	.method public static bool TestFilter (bool b) cil managed
+	{
+		.maxstack 2
+		.locals init (bool flag)
+	beginTry:
+		newobj instance void [mscorlib]System.Exception::.ctor ()
+		throw
+		leave endCatch
+	startFilter:
+		pop
+		ldarg.0
+		endfilter
+	startCatch:
+		ldc.i4.1
+		stloc.0
+		leave return
+		leave endCatch
+	endCatch:
+		L_001b: ldc.i4.0
+		L_001c: stloc.0
+	return:
+		L_001d: ldloc.0
+		L_001e: ret
+		.try beginTry to startFilter filter startFilter handler startCatch to endCatch
+	}
+
+	.method public static !!T GetState<T>(string var, [opt] !!T defaultValue) cil managed
+	{
+		.param [2] = nullref
+
+		ldarg.1
+		ret
+	}
+}

external/cecil-legacy/Test/Resources/il/methodspecs.il

@@ -0,0 +1,43 @@
+
+.assembly extern mscorlib
+{
+  .publickeytoken = (B7 7A 5C 56 19 34 E0 89 )
+  .ver 2:0:0:0
+}
+
+.assembly MethodSpecs
+{
+}
+
+.module MethodSpecs.dll
+
+.class private auto ansi beforefieldinit Tamtam
+       extends [mscorlib]System.Object
+{
+  .method private hidebysig static void  Foo<TFoo>(!!TFoo tf) cil managed
+  {
+    // Code size       1 (0x1)
+    .maxstack  8
+    IL_0000:  ret
+  } // end of method Tamtam::Foo
+
+  .method private hidebysig static void  Bar() cil managed
+  {
+    // Code size       7 (0x7)
+    .maxstack  8
+    IL_0000:  ldc.i4.2
+    IL_0001:  call       void Tamtam::Foo<int32>(!!0)
+    IL_0006:  ret
+  } // end of method Tamtam::Bar
+
+  .method public hidebysig specialname rtspecialname
+          instance void  .ctor() cil managed
+  {
+    // Code size       7 (0x7)
+    .maxstack  8
+    IL_0000:  ldarg.0
+    IL_0001:  call       instance void [mscorlib]System.Object::.ctor()
+    IL_0006:  ret
+  } // end of method Tamtam::.ctor
+
+} // end of class Tamtam

external/cecil-legacy/Test/Resources/il/others.il

@@ -0,0 +1,81 @@
+.assembly extern mscorlib
+{
+  .publickeytoken = (B7 7A 5C 56 19 34 E0 89)
+  .ver 2:0:0:0
+}
+
+.assembly Others {}
+
+.module Others.dll
+
+.class private auto ansi Others {
+
+	.field private string _context
+
+	.method public specialname instance string get_Context () cil managed
+	{
+		ldarg.0
+		ldfld string Others::_context
+		ret
+	}
+
+	.method public specialname instance void set_Context (string val) cil managed
+	{
+		ldarg.0
+		ldarg.1
+		stfld string Others::_context
+		ret
+	}
+
+	.method public specialname instance void let_Context (string val) cil managed
+	{
+		ldarg.0
+		ldarg.1
+		stfld string Others::_context
+		ret
+	}
+
+	.method public specialname instance void bet_Context (string val) cil managed
+	{
+		ldarg.0
+		ldarg.1
+		stfld string Others::_context
+		ret
+	}
+
+	.property instance string Context () {
+		.get instance string Others::get_Context ()
+		.set instance void Others::set_Context (string val)
+		.other instance void Others::let_Context (string val)
+		.other instance void Others::bet_Context (string val)
+	}
+
+	.field private class [mscorlib]System.EventHandler _handler
+
+	.method public specialname instance void remove_Handler (class [mscorlib]System.EventHandler) cil managed
+	{
+		ret
+	}
+
+	.method public specialname instance void add_Handler (class [mscorlib]System.EventHandler) cil managed
+	{
+		ret
+	}
+
+	.method public specialname instance void dang_Handler (class [mscorlib]System.EventHandler) cil managed
+	{
+		ret
+	}
+
+	.method public specialname instance void fang_Handler (class [mscorlib]System.EventHandler) cil managed
+	{
+		ret
+	}
+
+	.event [mscorlib]System.EventHandler Handler {
+		.removeon instance void Others::remove_Handler (class [mscorlib]System.EventHandler)
+		.addon instance void Others::add_Handler (class [mscorlib]System.EventHandler)
+		.other instance void Others::dang_Handler (class [mscorlib]System.EventHandler)
+		.other instance void Others::fang_Handler (class [mscorlib]System.EventHandler)
+	}
+}

external/cecil-legacy/Test/Resources/il/types.il

@@ -0,0 +1,58 @@
+.assembly extern mscorlib
+{
+  .publickeytoken = (B7 7A 5C 56 19 34 E0 89)
+  .ver 2:0:0:0
+}
+
+.assembly Types {}
+
+.module Types.dll
+
+.class private auto ansi Types {
+
+	.field public int32[,] rank_two
+	.field public int32[0...,0...] rank_two_low_bound_zero
+	.field public int32[-1...4] rank_one_low_bound_m1
+
+	.method public specialname rtspecialname instance void .ctor () cil managed
+	{
+		ldarg.0
+		call instance void [mscorlib]System.Object::.ctor ()
+		ret
+	}
+}
+
+.class interface private abstract auto ansi IFoo
+{
+}
+
+.class interface private abstract auto ansi IBar
+       implements IFoo
+{
+}
+
+.class interface private abstract IBaz
+       implements IBar, IFoo
+{
+}
+
+.class private Fields {
+
+	.field private static literal int32 int32_int16 = int16(0x0001)
+	.field private static literal int16 int16_int32 = int32(0x00000001)
+	.field private static literal char char_int16 = int16(0x0001)
+	.field private static literal int16 int16_char = char(0x0073)
+	.field private static literal int32 int32_nullref = nullref
+}
+
+.class public auto ansi CustomAttribute extends [mscorlib]System.Attribute
+{
+	.custom instance void CustomAttribute::.ctor() = ()
+
+	.method public hidebysig specialname rtspecialname instance void .ctor()
+	{
+		ldarg.0
+		call instance void [mscorlib]System.Attribute::.ctor()
+		ret
+	}
+}