mirror of
https://github.com/macports/macports-ports.git
synced 2026-07-12 18:20:25 -07:00
Fred WrightandRenee Otten
f1dddc92d1
See: https://www.ruby-lang.org/en/news/2026/03/27/ruby-3-2-11-released/ Also disables the unnecessary compiler wrapper, and adds a warning about tests. TESTED: Built successfully on OSX 10.4-10.6 i386, 10.5-12.x x86_64, and 11.x-26.x arm64. Included all variants compatible with available dependencies on the respective platforms.
217 lines
7.6 KiB
Plaintext
217 lines
7.6 KiB
Plaintext
# -*- coding: utf-8; mode: tcl; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- vim:fenc=utf-8:et:sw=4:ts=4:sts=4
|
|
|
|
PortSystem 1.0
|
|
PortGroup select 1.0
|
|
PortGroup openssl 1.0
|
|
PortGroup legacysupport 1.1
|
|
|
|
# MAP_ANONYMOUS
|
|
legacysupport.newest_darwin_requires_legacy 14
|
|
|
|
# Version updates should start by updating the fork noted below
|
|
# (or equivalent), verifying the propriety of the patches for the new version,
|
|
# and rederiving the patchfile from there.
|
|
#
|
|
# Also note that this port runs on all OS/CPU combinations.
|
|
# This property should be preserved.
|
|
|
|
set ruby_ver 3.2
|
|
set ruby_patch 11
|
|
set ruby_ver_nodot [string map {. {}} ${ruby_ver}]
|
|
name ruby${ruby_ver_nodot}
|
|
version ${ruby_ver}.${ruby_patch}
|
|
revision 0
|
|
|
|
categories lang ruby
|
|
maintainers {kimuraw @kimuraw} \
|
|
{fwright.net:fw @fhgwright} \
|
|
openmaintainer
|
|
|
|
description Powerful and clean object-oriented scripting language
|
|
long_description Ruby is the interpreted scripting language for quick \
|
|
and easy object-oriented programming. It has many \
|
|
features to process text files and to do system \
|
|
management tasks (as in Perl). It is simple, \
|
|
straightforward, extensible, and portable.
|
|
|
|
homepage https://www.ruby-lang.org/
|
|
license {Ruby BSD}
|
|
|
|
master_sites ruby:${ruby_ver}
|
|
distname ruby-${version}
|
|
dist_subdir ruby${ruby_ver_nodot}
|
|
|
|
checksums rmd160 7e54815e44c1293effcc370f9b6b0e03fee619f1 \
|
|
sha256 b3eeabd6636f334531db3ffdc3229eb05e524740e6c84fdc043720573cf2f8b2 \
|
|
size 19984344
|
|
|
|
# Universal builds don't currently work, including via the approach used
|
|
# in ruby30.
|
|
universal_variant no
|
|
|
|
# ruby/openssl since ruby-3.2 supports openssl-3
|
|
openssl.branch 3
|
|
|
|
depends_lib port:readline \
|
|
port:zlib \
|
|
port:libyaml \
|
|
port:libffi \
|
|
port:gdbm
|
|
depends_run port:ruby_select
|
|
depends_build port:pkgconfig port:cctools
|
|
depends_skip_archcheck pkgconfig
|
|
|
|
select.group ruby
|
|
select.file ${filespath}/ruby${ruby_ver_nodot}
|
|
|
|
# Patches derived from MacPorts-enhanced GitHub fork at
|
|
# github.com/fhgwright/ruby
|
|
|
|
# patch-sources.diff: fixes for various issues.
|
|
# This includes the 'gem' versioning fix formerly handled via reinplace.
|
|
#
|
|
# This diff is from v3_2_11 vs. macports-3_2_11.
|
|
#
|
|
patchfiles-append patch-sources.diff
|
|
|
|
#-------------------------------------------------------------------------------
|
|
# Fix compilation on 10.12.
|
|
# Issue: 62183: error: use of undeclared identifier 'fmt'; did you mean 'fma'?
|
|
#
|
|
# This issue only appears in Xcode clang 9 (clang 900), not MacPorts clang 9
|
|
# (clang 901), so the blacklisting can be narrow.
|
|
#-------------------------------------------------------------------------------
|
|
compiler.blacklist-append { clang >= 900 < 901 }
|
|
|
|
# Ruby3.2+ doesn't build with Xcode clang 425 on 10.7
|
|
compiler.blacklist-append { clang < 500 }
|
|
|
|
# Ensure that the correct dsymutil is used.
|
|
if { [string match macports-clang-* ${configure.compiler}] } {
|
|
# clang-mp-14 => dsymutil-mp-14; fix POSTLINK
|
|
configure.env-append dsymutil=[string map {clang dsymutil} ${configure.cc}]
|
|
}
|
|
|
|
compiler.thread_local_storage yes
|
|
|
|
# At least one version of clang doesn't offer cstdbool (introduced in C++11)
|
|
# with -stdlib=libstc++ but still reports as C++14. This causes an include
|
|
# failure in include/ruby/internal/stdbool.h when built as C++. Setting the
|
|
# standard to C++03 removes the expectation that cstdbool is available.
|
|
#
|
|
# This has only been observed when building for 10.5, and in fact, ruby
|
|
# makes very little use of C++, and would probably be fine if this were
|
|
# unconditional. Nevertheless, we limit it to the failing case.
|
|
#
|
|
if {[string match *clang* ${configure.compiler}] \
|
|
&& ${configure.cxx_stdlib} eq "libstdc++"} {
|
|
configure.cxxflags-append -std=c++03
|
|
}
|
|
|
|
# The openssl PG brings in the unnecessary compiler_wrapper PG.
|
|
# Disable it to reduce logfile clutter and obfuscation.
|
|
#
|
|
compwrap.compilers_to_wrap
|
|
|
|
configure.args --enable-shared \
|
|
--enable-install-static-library \
|
|
--disable-install-doc \
|
|
--mandir="${prefix}/share/man" \
|
|
--enable-pthread \
|
|
--disable-yjit \
|
|
--without-gmp \
|
|
--without-jemalloc \
|
|
--with-opt-dir="${prefix}" \
|
|
--program-suffix=${ruby_ver} \
|
|
--with-rubyhdrdir=${prefix}/include/ruby-${version} \
|
|
--with-rubylibprefix="${prefix}/lib/ruby${ruby_ver}" \
|
|
--with-openssl-dir=[openssl::install_area] \
|
|
--without-baseruby \
|
|
--with-arch="${build_arch}"
|
|
# prefer Apple cctools to GNU binutils, build with binutils may fail.
|
|
configure.args-append AR=${prefix}/bin/ar RANLIB=${prefix}/bin/ranlib
|
|
|
|
post-destroot {
|
|
foreach type {site vendor} {
|
|
set libdir ${destroot}${prefix}/lib/ruby${ruby_ver}/${type}_ruby/${version}
|
|
xinstall -m 0755 -d ${libdir}
|
|
foreach subdir [exec find ${libdir} -type d -empty] {
|
|
destroot.keepdirs-append ${subdir}
|
|
}
|
|
}
|
|
|
|
# install destination of commands from port:ruby32
|
|
xinstall -m 0755 -d ${destroot}${prefix}/libexec/ruby${ruby_ver}
|
|
destroot.keepdirs-append ${destroot}${prefix}/libexec/ruby${ruby_ver}
|
|
}
|
|
|
|
notes-append "
|
|
To make this the default Ruby (i.e., the version run by\
|
|
the 'ruby', 'gem' or 'bundle' commands), run:
|
|
sudo port select --set ruby $name
|
|
"
|
|
|
|
variant doc description "Install rdoc indexes and C API documents" {
|
|
configure.args-delete --disable-install-doc
|
|
}
|
|
|
|
variant gmp description "use gmp" {
|
|
configure.args-delete --without-gmp
|
|
depends_lib-append port:gmp
|
|
}
|
|
|
|
variant jemalloc description "use jemalloc" {
|
|
configure.args-replace --without-jemalloc --with-jemalloc
|
|
depends_lib-append port:jemalloc
|
|
}
|
|
|
|
variant yjit description "enable YJIT (requires rust)" {
|
|
configure.args-replace --disable-yjit --enable-yjit
|
|
depends_build-append port:rust
|
|
}
|
|
# yjit supports x86_64 or arm64
|
|
if {${os.platform} eq "darwin" && ${os.major} >= 19 \
|
|
&& [info exists build_arch]} {
|
|
if {$build_arch in [list x86_64 arm64]} {
|
|
default_variants-append +yjit
|
|
}
|
|
}
|
|
|
|
variant relative description "Enable relative loading of libraries to allow for relocation of binaries." {
|
|
#enable relative loading
|
|
configure.args-append --enable-load-relative
|
|
}
|
|
|
|
# legacy systems support
|
|
platform darwin {
|
|
if {${os.major} < 10} {
|
|
# Disable broken compiler
|
|
compiler.blacklist-append macports-gcc-15
|
|
# libdtrace lacks a 64-bit slice
|
|
if { [string match *64 ${build_arch}] } {
|
|
configure.args-append --disable-dtrace
|
|
}
|
|
}
|
|
|
|
if {${os.major} == 8} {
|
|
configure.cppflags-append -DCPU_SUBTYPE_MASK=0xff000000
|
|
depends_build-append port:gmake
|
|
build.cmd ${prefix}/bin/gmake
|
|
compiler.blacklist-append macports-clang-*
|
|
}
|
|
}
|
|
|
|
# Tests don't fully pass on any platform, though the details are platform-
|
|
# dependent. We allow them for investigative purposes, along with a warning.
|
|
|
|
test.run yes
|
|
test.target check
|
|
|
|
pre-test {
|
|
ui_warn "Tests are not expected to fully pass."
|
|
}
|
|
|
|
livecheck.type regex
|
|
livecheck.url https://cache.ruby-lang.org/pub/ruby/${ruby_ver}/
|
|
livecheck.regex ruby-(3\\.2\\.\\d+)[quotemeta ${extract.suffix}]
|