macports/macports-ports
0
0
Fork 0
mirror of https://github.com/macports/macports-ports.git synced 2026-07-12 18:20:25 -07:00
Code Issues Packages Projects Releases Wiki Activity
Files
python_variants
macports-ports/lang/gcc6/Portfile
T

335 lines
14 KiB
Tcl
Raw Permalink Blame History

# -*- coding: utf-8; mode: tcl; tab-width: 4; indent-tabs-mode: nil; c-basic-offset: 4 -*- vim:fenc=utf-8:filetype=tcl:et:sw=4:ts=4:sts=4
PortSystem 1.0
PortGroup select 1.0
PortGroup conflicts_build 1.0
PortGroup xcode_workaround 1.0
name gcc6
epoch 3
version 6.5.0
revision 7
subport libgcc6 { revision 4 }
platforms {darwin < 15}
categories lang
maintainers nomaintainer
# an exception in the license allows dependents to not be GPL
license {GPL-3+ Permissive}
description The GNU compiler collection
long_description The GNU compiler collection, including front ends for \
C, C++, Objective-C, Objective-C++ and Fortran.
homepage https://gcc.gnu.org/
master_sites ftp://ftp.funet.fi/pub/mirrors/sources.redhat.com/pub/gcc/releases/gcc-${version}/ \
ftp://ftp.gwdg.de/pub/linux/gcc/releases/gcc-${version}/ \
ftp://gcc.ftp.nluug.nl/mirror/languages/gcc/releases/gcc-${version}/ \
ftp://gcc.gnu.org/pub/gcc/releases/gcc-${version}/ \
gnu:gcc/gcc-${version}
distname gcc-${version}
use_xz yes
checksums rmd160 66782b17cff89f22e5e8869fa96bd9a8985f5067 \
sha256 7ef1796ce497e89479183702635b14bb7a46b53249209a5e0f999bebf4740945 \
size 74355588
if { ${configure.build_arch} eq "i386" && ${os.major} >= 10 } {
# fix no-pie clang bug bootstrapping gcc on i386
# https://trac.macports.org/ticket/63161
patchfiles-append patch-gcc7-i686-clang-bootstrap-fix.diff
# build with traditional "gas" assembler in all cases
# upstream does not typically test gcc with clang as assembler on i386 systems
# gcc configuration changes with assembler features
# also innumerable warnings about text section naming suppressed
patchfiles-append patch-gcc7-disable-macports-cctools-as-changes.diff
configure.env-append \
"DISABLE_MACPORTS_AS_CLANG_SEARCH=1" \
"DISABLE_XCODE_AS_CLANG_SEARCH=1"
build.env-append \
"DISABLE_MACPORTS_AS_CLANG_SEARCH=1" \
"DISABLE_XCODE_AS_CLANG_SEARCH=1"
}
depends_lib port:cctools \
port:gmp \
path:lib/pkgconfig/isl.pc:isl \
port:ld64 \
port:zlib \
port:libiconv \
port:libmpc \
port:mpfr
depends_run port:gcc_select \
port:libgcc6
depends_skip_archcheck-append gcc_select ld64 cctools
license_noconflict gmp mpfr ppl libmpc
# Work around parallel building issue on APFS
# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=81797
patchfiles-append notparallel-install-headers.patch
if {[vercmp ${xcodeversion} 10.2] >= 0} {
# https://trac.macports.org/ticket/58260
# Patch for Xcode bug, taken from
# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=89864#c43
# https://github.com/Homebrew/homebrew-core/pull/39134/files
# This should be removed in the next release of GCC
patchfiles-append xcode-bug-_Atomic-fix.patch
}
set major [lindex [split ${version} .-] 0]
platform darwin {
configure.pre_args-append --build=${build_arch}-apple-darwin${os.major}
# see https://gcc.gnu.org/ml/gcc-patches/2012-05/msg00672.html
patchfiles-append patch-float128.diff
}
# fix build on Tiger Intel - same patch as gcc7 / libgcc works
platform darwin 8 i386 {
patchfiles-append patch-gcc7-tiger-intel.diff
}
configure.dir ${workpath}/build
configure.cmd ${worksrcpath}/configure
configure.args --enable-languages=c,c++,objc,obj-c++,lto,fortran \
--libdir=${prefix}/lib/${name} \
--includedir=${prefix}/include/${name} \
--infodir=${prefix}/share/info \
--mandir=${prefix}/share/man \
--datarootdir=${prefix}/share/gcc-${major} \
--with-local-prefix=${prefix} \
--with-system-zlib \
--disable-nls \
--program-suffix=-mp-${major} \
--with-gxx-include-dir=${prefix}/include/${name}/c++/ \
--with-gmp=${prefix} \
--with-mpfr=${prefix} \
--with-mpc=${prefix} \
--with-isl=${prefix} \
--enable-stage1-checking \
--disable-multilib \
--enable-lto \
--enable-libstdcxx-time \
--with-build-config=bootstrap-debug \
--with-as=${prefix}/bin/as \
--with-ld=${prefix}/bin/ld \
--with-ar=${prefix}/bin/ar \
--with-bugurl=https://trac.macports.org/newticket
# see https://lists.macports.org/pipermail/macports-dev/2017-August/036209.html
# --disable-tls does not limit functionality
# it only determines how std::call_once works
configure.args-append \
--disable-tls
configure.env-append \
AR_FOR_TARGET=${prefix}/bin/ar \
AS_FOR_TARGET=${prefix}/bin/as \
LD_FOR_TARGET=${prefix}/bin/ld \
NM_FOR_TARGET=${prefix}/bin/nm \
OBJDUMP_FOR_TARGET=${prefix}/bin/objdump \
RANLIB_FOR_TARGET=${prefix}/bin/ranlib \
STRIP_FOR_TARGET=${prefix}/bin/strip \
OTOOL=${prefix}/bin/otool \
OTOOL64=${prefix}/bin/otool
pre-configure {
configure.args-append --with-pkgversion="MacPorts ${name} ${version}_${revision}${portvariants}"
if {${configure.sdkroot} ne ""} {
# We should be using --with-build-sysroot here. Using --with-sysroot
# changes the behavior of the installed gcc to look in that sysroot
# by default instead of /. Using --with-build-sysroot is supposed
# to be used during the build but not impact the installed product.
# Unfortunately, the build fails because the value doesn't get
# plumbed everywhere it is supposed to.
#
# https://trac.macports.org/ticket/53726
# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=79885
#
# Note that macports toolchains will fail to compile gcc unless
# the DevSDK is installed due to another gcc build system bug:
# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=80203
configure.args-append --with-sysroot="${configure.sdkroot}"
}
# TODO: Remove when base automatically creates configure.dir (2.2.1?).
file mkdir ${configure.dir}
}
# gcc cannot build if libunwind-headers is active
conflicts_build-append libunwind-headers
# http://trac.macports.org/ticket/29067
compiler.blacklist-append gcc-4.0
# http://trac.macports.org/ticket/29104
compiler.blacklist-append {llvm-gcc-4.2 < 2336.1}
# https://trac.macports.org/ticket/47996
compiler.blacklist-append {clang < 300}
# "-stdlib" would be passed on to the bootstrap compiler if present
configure.cxx_stdlib
build.dir ${configure.dir}
build.target bootstrap-lean
use_parallel_build yes
destroot.target install install-info-host
if {${subport} eq "libgcc6"} {
# http://trac.macports.org/ticket/35770
# http://trac.macports.org/ticket/38814
# While there can be multiple versions of these runtimes in a single
# process, it is not possible to pass objects between different versions,
# so we simplify this by having the libgcc port provide the newest version
# of these runtimes for all versions of gcc to use.
#
# If there is a binary incompatible change to the runtime in a future
# version of gcc, then the latest version of gcc to provide a given ABI
# version should continue to provide a subport for that and older gcc
# versions.
depends_run port:libgcc7
depends_build-append {*}${depends_lib}
depends_lib
configure.args-replace \
--libdir=${prefix}/lib/${name} \
--libdir=${prefix}/lib/libgcc
configure.args-replace \
--enable-languages=c,c++,objc,obj-c++,lto,fortran \
--enable-languages=fortran
# TODO: Possibly disable bootstrap with appropriate configure flags.
# the problem is that libstdc++'s configure script tests for tls support
# using the running compiler (not gcc for which libstdc++ is being built).
# Thus when we build with clang, we get a mismatch
# http://trac.macports.org/ticket/36116
#compiler.blacklist-append {clang < 425}
#configure.args-append --disable-bootstrap
#build.target all
post-destroot {
file mkdir ${destroot}${prefix}/lib/libgcc.merged
# We need to list libquadmath.0.dylib here even though it isn't installed in order to make sure we cleanup libgfortran.3.dylib's linkage when +universal
# See https://trac.macports.org/ticket/54768
set dylibs {libgfortran.3.dylib libquadmath.0.dylib libasan.3.dylib}
foreach dylib ${dylibs} {
# Different OS versions (e.g. Leopard) or architectures (e.g. PPC) don't produce all the dylibs
# https://trac.macports.org/ticket/40098
# https://trac.macports.org/ticket/40100
if {! [file exists ${destroot}${prefix}/lib/libgcc/${dylib}]} {
continue
}
move ${destroot}${prefix}/lib/libgcc/${dylib} ${destroot}${prefix}/lib/libgcc.merged
if {[variant_exists universal] && [variant_isset universal]} {
foreach archdir [glob ${destroot}${prefix}/lib/libgcc/*/] {
set archdir_nodestroot [string map "${destroot}/ /" ${archdir}]
if {[file exists ${archdir}/${dylib}]} {
system "install_name_tool -id ${prefix}/lib/libgcc/${dylib} ${archdir}/${dylib}"
foreach link [glob -tails -directory ${archdir} *.dylib] {
system "install_name_tool -change ${archdir_nodestroot}${link} ${prefix}/lib/libgcc/${link} ${archdir}/${dylib}"
}
system "lipo -create -output ${destroot}${prefix}/lib/libgcc.merged/${dylib}~ ${destroot}${prefix}/lib/libgcc.merged/${dylib} ${archdir}/${dylib} && mv ${destroot}${prefix}/lib/libgcc.merged/${dylib}~ ${destroot}${prefix}/lib/libgcc.merged/${dylib}"
}
}
}
# strip debug symbols to supress debugger warnings:
# http://trac.macports.org/attachment/ticket/34831
if {! [string match *libgcc_ext* ${dylib}]} {
system "strip -x ${destroot}${prefix}/lib/libgcc.merged/${dylib}"
}
}
file delete -force ${destroot}${prefix}/bin
file delete -force ${destroot}${prefix}/share
file delete -force ${destroot}${prefix}/include
file delete -force ${destroot}${prefix}/lib/libgcc
file delete -force ${destroot}${prefix}/libexec
move ${destroot}${prefix}/lib/libgcc.merged ${destroot}${prefix}/lib/libgcc
# This is provided by the libgcc port
file delete -force ${destroot}${prefix}/lib/libgcc/libquadmath.0.dylib
}
} else {
post-destroot {
file delete ${destroot}${prefix}/share/info/dir
foreach file [glob ${destroot}${prefix}/share/{info,man/man7}/*] {
set extension [file extension ${file}]
set newfile [regsub "${extension}$" ${file} "-mp-${major}${extension}"]
file rename ${file} ${newfile}
}
foreach dylib {libgcc_ext.10.4.dylib libgcc_ext.10.5.dylib libgcc_s.1.dylib libgfortran.3.dylib libquadmath.0.dylib libstdc++.6.dylib libobjc-gnu.4.dylib libgomp.1.dylib libitm.1.dylib libssp.0.dylib libasan.3.dylib libatomic.1.dylib} {
# Different OS versions (e.g. Leopard) or architectures (e.g. PPC) don't produce all the dylibs
# https://trac.macports.org/ticket/40098
# https://trac.macports.org/ticket/40100
if {[file exists ${destroot}${prefix}/lib/${name}/${dylib}]} {
delete ${destroot}${prefix}/lib/${name}/${dylib}
ln -s ${prefix}/lib/libgcc/${dylib} ${destroot}${prefix}/lib/${name}/${dylib}
}
if {[variant_exists universal] && [variant_isset universal]} {
foreach archdir [glob ${destroot}${prefix}/lib/${name}/*/] {
if {[file exists ${archdir}/${dylib}]} {
delete ${archdir}/${dylib}
ln -s ${prefix}/lib/libgcc/${dylib} ${archdir}/${dylib}
}
}
}
}
}
select.group gcc
select.file ${filespath}/mp-${name}
}
platform powerpc {
configure.universal_archs ppc ppc64
}
platform i386 {
configure.universal_archs i386 x86_64
}
variant universal {
configure.args-delete --disable-multilib
}
# the generated compiler doesn't accept -arch
configure.env-append \
"CPP=${configure.cc} -E" \
"CXXCPP=${configure.cxx} -E"
build.env-append \
"CPP=${configure.cc} -E" \
"CXXCPP=${configure.cxx} -E"
configure.cc-append [get_canonical_archflags]
configure.cc_archflags
configure.cxx-append ${configure.cxx_archflags}
configure.cxx_archflags
configure.objc_archflags
configure.ld_archflags
configure.universal_cflags
configure.universal_cxxflags
configure.universal_ldflags
configure.universal_args
livecheck.type regex
livecheck.url https://ftp.gnu.org/gnu/gcc/
livecheck.regex gcc-(${major}\\.\[0-9.\]+)/
Reference in New Issue View Git Blame Copy Permalink