AC_PREREQ(2.59)
AC_INIT(configure.in)

AC_CANONICAL_HOST

AC_SEARCH_LIBS([ioperm], [ioperm])
AC_SEARCH_LIBS([dlopen], [dl])

AC_CHECK_HEADERS(jtag_minidriver.h)
AC_CHECK_HEADERS(sys/param.h)
AC_CHECK_HEADERS(sys/time.h)
AC_CHECK_HEADERS(elf.h)
AC_CHECK_HEADERS(strings.h)

AC_HEADER_TIME

AC_C_BIGENDIAN

AC_CHECK_FUNCS(strndup)
AC_CHECK_FUNCS(strnlen)
AC_CHECK_FUNCS(gettimeofday)
AC_CHECK_FUNCS(usleep)
AC_CHECK_FUNCS(vasprintf)

build_bitbang=no
build_bitq=no
is_cygwin=no
is_mingw=no
is_win32=no

AC_ARG_ENABLE(gccwarnings,
	AS_HELP_STRING([--enable-gccwarnings], [Enable compiler warnings, default no]),
	[gcc_warnings=$enableval], [gcc_warnings=no])

AC_ARG_ENABLE(parport,
  AS_HELP_STRING([--enable-parport], [Enable building the pc parallel port driver]), 
  [build_parport=$enableval], [build_parport=no])

AC_ARG_ENABLE(dummy,
  AS_HELP_STRING([--enable-dummy], [Enable building the dummy port driver]), 
  [build_dummy=$enableval], [build_dummy=no])
  
case "${host_cpu}" in 
  i?86|x86*)
    AC_ARG_ENABLE(parport_ppdev,
      AS_HELP_STRING([--enable-parport_ppdev], [Enable use of ppdev (/dev/parportN) for parport]), 
      [parport_use_ppdev=$enableval], [parport_use_ppdev=no])
    ;;
  *) 
    parport_use_ppdev=yes
    ;;
esac

AC_ARG_ENABLE(ft2232_libftdi,
  AS_HELP_STRING([--enable-ft2232_libftdi], [Enable building support for FT2232 based devices using the libftdi driver]), 
  [build_ft2232_libftdi=$enableval], [build_ft2232_libftdi=no])

AC_ARG_ENABLE(ft2232_ftd2xx,
  AS_HELP_STRING([--enable-ft2232_ftd2xx], [Enable building support for FT2232 based devices using the FTD2XX driver]), 
  [build_ft2232_ftd2xx=$enableval], [build_ft2232_ftd2xx=no])
 
AC_ARG_ENABLE(amtjtagaccel,
  AS_HELP_STRING([--enable-amtjtagaccel], [Enable building the Amontec JTAG-Accelerator driver]), 
  [build_amtjtagaccel=$enableval], [build_amtjtagaccel=no])

case "${host_cpu}" in 
  arm*)
    AC_ARG_ENABLE(ep93xx,
      AS_HELP_STRING([--enable-ep93xx], [Enable building support for EP93xx based SBCs]), 
      [build_ep93xx=$enableval], [build_ep93xx=no])

	AC_ARG_ENABLE(ecosboard,
	  AS_HELP_STRING([--enable-ecosboard], [Enable building support for eCosBoard based JTAG debugger]), 
	  [build_ecosboard=$enableval], [build_ecosboard=no])

    AC_ARG_ENABLE(at91rm9200,
      AS_HELP_STRING([--enable-at91rm9200], [Enable building support for AT91RM9200 based SBCs]),
      [build_at91rm9200=$enableval], [build_at91rm9200=no])
    ;;
    
  *) 
    build_ep93xx=no
    build_at91rm9200=no
	build_ecosboard=no
    ;;
esac

AC_ARG_ENABLE(gw16012,
  AS_HELP_STRING([--enable-gw16012], [Enable building support for the Gateworks GW16012 JTAG Programmer]),
  [build_gw16012=$enableval], [build_gw16012=no])

AC_ARG_ENABLE(presto_libftdi,
  AS_HELP_STRING([--enable-presto_libftdi], [Enable building support for ASIX Presto Programmer using the libftdi driver]),
  [build_presto_libftdi=$enableval], [build_presto_libftdi=no])

AC_ARG_ENABLE(presto_ftd2xx,
  AS_HELP_STRING([--enable-presto_ftd2xx], [Enable building support for ASIX Presto Programmer using the FTD2XX driver]),
  [build_presto_ftd2xx=$enableval], [build_presto_ftd2xx=no])

AC_ARG_ENABLE(usbprog,
  AS_HELP_STRING([--enable-usbprog], [Enable building support for the usbprog JTAG Programmer]),
  [build_usbprog=$enableval], [build_usbprog=no])

AC_ARG_ENABLE(oocd_trace,
  AS_HELP_STRING([--enable-oocd_trace], [Enable building support for the OpenOCD+trace ETM capture device]),
  [build_oocd_trace=$enableval], [build_oocd_trace=no])

AC_ARG_ENABLE(jlink,
  AS_HELP_STRING([--enable-jlink], [Enable building support for the Segger J-Link JTAG Programmer]),
  [build_jlink=$enableval], [build_jlink=no])

AC_ARG_WITH(ftd2xx,
        [AS_HELP_STRING(--with-ftd2xx,
           [Where libftd2xx can be found <default=search>])],
        [],
        with_ftd2xx=search)

case $host in 
  *-cygwin*) 
    is_win32=yes

    AC_ARG_ENABLE(parport_giveio,
    AS_HELP_STRING([--enable-parport_giveio], [Enable use of giveio for parport instead of ioperm]), 
    [parport_use_giveio=$enableval], [parport_use_giveio=no])
	
	AC_COMPILE_IFELSE(AC_LANG_PROGRAM([],[return __MINGW32__;]),[is_mingw=yes],[is_mingw=no])
	if test $is_mingw = yes; then
		AC_DEFINE(IS_MINGW, 1, [1 if building for MinGW.])
		parport_use_giveio=yes
		is_cygwin=no
	else
		is_cygwin=yes
		AC_DEFINE(IS_CYGWIN, 1, [1 if building for Cygwin.])
	fi
	
    AC_DEFINE(IS_WIN32, 1, [1 if building for Win32.])
    ;; 
  *-mingw*) 
    is_mingw=yes
    is_win32=yes

    parport_use_giveio=yes

    AC_DEFINE(IS_MINGW, 1, [1 if building for MinGW.])
    AC_DEFINE(IS_WIN32, 1, [1 if building for Win32.])
    ;; 
  *) 
	parport_use_giveio=no
    AC_DEFINE(IS_CYGWIN, 0, [0 if not building for Cygwin.])
    AC_DEFINE(IS_WIN32, 0, [0 if not building for Win32.])
    ;;
esac

if test $build_parport = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_PARPORT, 1, [1 if you want parport.])
else
  AC_DEFINE(BUILD_PARPORT, 0, [0 if you don't want parport.])
fi

if test $build_dummy = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_DUMMY, 1, [1 if you want dummy driver.])
else
  AC_DEFINE(BUILD_DUMMY, 0, [0 if you don't want dummy driver.])
fi


if test $build_ep93xx = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_EP93XX, 1, [1 if you want ep93xx.])
else
  AC_DEFINE(BUILD_EP93XX, 0, [0 if you don't want ep93xx.])
fi

if test $build_ecosboard = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_ECOSBOARD, 1, [1 if you want eCosBoard.])
else
  AC_DEFINE(BUILD_ECOSBOARD, 0, [0 if you don't want eCosBoard.])
fi

if test $build_at91rm9200 = yes; then
  build_bitbang=yes
  AC_DEFINE(BUILD_AT91RM9200, 1, [1 if you want at91rm9200.])
else
  AC_DEFINE(BUILD_AT91RM9200, 0, [0 if you don't want at91rm9200.])
fi

if test $parport_use_ppdev = yes; then
  AC_DEFINE(PARPORT_USE_PPDEV, 1, [1 if you want parport to use ppdev.])
else
  AC_DEFINE(PARPORT_USE_PPDEV, 0, [0 if you don't want parport to use ppdev.])
fi

if test $parport_use_giveio = yes; then
  AC_DEFINE(PARPORT_USE_GIVEIO, 1, [1 if you want parport to use giveio.])
else
  AC_DEFINE(PARPORT_USE_GIVEIO, 0, [0 if you don't want parport to use giveio.])
fi

if test $build_bitbang = yes; then
  AC_DEFINE(BUILD_BITBANG, 1, [1 if you want a bitbang interface.])
else
  AC_DEFINE(BUILD_BITBANG, 0, [0 if you don't want a bitbang interface.])
fi

if test $build_ft2232_libftdi = yes; then
  AC_DEFINE(BUILD_FT2232_LIBFTDI, 1, [1 if you want libftdi ft2232.])
else
  AC_DEFINE(BUILD_FT2232_LIBFTDI, 0, [0 if you don't want libftdi ft2232.])
fi

if test $build_ft2232_ftd2xx = yes; then
  AC_DEFINE(BUILD_FT2232_FTD2XX, 1, [1 if you want ftd2xx ft2232.])
else
  AC_DEFINE(BUILD_FT2232_FTD2XX, 0, [0 if you don't want ftd2xx ft2232.])
fi

if test $build_amtjtagaccel = yes; then
  AC_DEFINE(BUILD_AMTJTAGACCEL, 1, [1 if you want the Amontec JTAG-Accelerator driver.])
else
  AC_DEFINE(BUILD_AMTJTAGACCEL, 0, [0 if you don't want the Amontec JTAG-Accelerator driver.])
fi

if test $build_gw16012 = yes; then
  AC_DEFINE(BUILD_GW16012, 1, [1 if you want the Gateworks GW16012 driver.])
else
  AC_DEFINE(BUILD_GW16012, 0, [0 if you don't want the Gateworks GW16012 driver.])
fi

if test $build_presto_libftdi = yes; then
  build_bitq=yes
  AC_DEFINE(BUILD_PRESTO_LIBFTDI, 1, [1 if you want the ASIX PRESTO driver using libftdi.])
else
  AC_DEFINE(BUILD_PRESTO_LIBFTDI, 0, [0 if you don't want the ASIX PRESTO driver using libftdi.])
fi

if test $build_presto_ftd2xx = yes; then
  build_bitq=yes
  AC_DEFINE(BUILD_PRESTO_FTD2XX, 1, [1 if you want the ASIX PRESTO driver using FTD2XX.])
else
  AC_DEFINE(BUILD_PRESTO_FTD2XX, 0, [0 if you don't want the ASIX PRESTO driver using FTD2XX.])
fi

if test $build_bitq = yes; then
  AC_DEFINE(BUILD_BITQ, 1, [1 if you want a bitq interface.])
else
  AC_DEFINE(BUILD_BITQ, 0, [0 if you don't want a bitq interface.])
fi

if test $build_usbprog = yes; then
  AC_DEFINE(BUILD_USBPROG, 1, [1 if you want the usbprog JTAG driver.])
else
  AC_DEFINE(BUILD_USBPROG, 0, [0 if you don't want the usbprog JTAG driver.])
fi

if test $build_oocd_trace = yes; then
  AC_DEFINE(BUILD_OOCD_TRACE, 1, [1 if you want the OpenOCD+trace ETM capture driver.])
else
  AC_DEFINE(BUILD_OOCD_TRACE, 0, [0 if you don't want the OpenOCD+trace ETM capture driver.])
fi

if test $build_jlink = yes; then
  AC_DEFINE(BUILD_JLINK, 1, [1 if you want the J-Link JTAG driver.])
else
  AC_DEFINE(BUILD_JLINK, 0, [0 if you don't want the J-Link JTAG driver.])
fi

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(openocd, 1.0)

AM_CONDITIONAL(PARPORT, test $build_parport = yes)
AM_CONDITIONAL(DUMMY, test $build_dummy = yes)
AM_CONDITIONAL(GIVEIO, test $parport_use_giveio = yes)
AM_CONDITIONAL(EP93XX, test $build_ep93xx = yes)
AM_CONDITIONAL(ECOSBOARD, test $build_ecosboard = yes)
AM_CONDITIONAL(AT91RM9200, test $build_at91rm9200 = yes)
AM_CONDITIONAL(BITBANG, test $build_bitbang = yes)
AM_CONDITIONAL(FT2232_LIBFTDI, test $build_ft2232_libftdi = yes)
AM_CONDITIONAL(FT2232_FTD2XX, test $build_ft2232_ftd2xx = yes)
AM_CONDITIONAL(AMTJTAGACCEL, test $build_amtjtagaccel = yes)
AM_CONDITIONAL(GW16012, test $build_gw16012 = yes)
AM_CONDITIONAL(PRESTO_LIBFTDI, test $build_presto_libftdi = yes)
AM_CONDITIONAL(PRESTO_FTD2XX, test $build_presto_ftd2xx = yes)
AM_CONDITIONAL(USBPROG, test $build_usbprog = yes)
AM_CONDITIONAL(OOCD_TRACE, test $build_oocd_trace = yes)
AM_CONDITIONAL(JLINK, test $build_jlink = yes)
AM_CONDITIONAL(IS_CYGWIN, test $is_cygwin = yes)
AM_CONDITIONAL(IS_MINGW, test $is_mingw = yes)
AM_CONDITIONAL(IS_WIN32, test $is_win32 = yes)
AM_CONDITIONAL(FTD2XXDIR, test $with_ftd2xx != search)
AM_CONDITIONAL(BITQ, test $build_bitq = yes)

AC_LANG_C
AC_PROG_CC
AC_PROG_RANLIB

# set default gcc warnings
GCC_WARNINGS="-Wall -Wstrict-prototypes"

# overide default gcc cflags
if test $gcc_warnings = yes; then
	CFLAGS="$CFLAGS $GCC_WARNINGS"
fi

# Setup for compiling build tools
AC_MSG_CHECKING([for a C compiler for build tools])
if test $cross_compiling = yes; then
	AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
	CFLAGS_FOR_BUILD="-g -O2 $GCC_WARNINGS"
else
	CC_FOR_BUILD=$CC
	CFLAGS_FOR_BUILD=$CFLAGS
fi

AC_MSG_RESULT([$CC_FOR_BUILD])
AC_SUBST(CC_FOR_BUILD)
AC_SUBST(CFLAGS_FOR_BUILD)

AC_MSG_CHECKING([for suffix of executable build tools])
if test $cross_compiling = yes; then
	cat >conftest.c <<\_______EOF
int main ()
{
	exit (0);
}
_______EOF
for i in .exe ""; do
    compile="$CC_FOR_BUILD conftest.c -o conftest$i"
    if AC_TRY_EVAL(compile); then
		if (./conftest) 2>&AC_FD_CC; then
			EXEEXT_FOR_BUILD=$i
			break
			fi
		fi
done
	rm -f conftest*
	if test "${EXEEXT_FOR_BUILD+set}" != set; then
		AC_MSG_ERROR([Cannot determine suffix of executable build tools])
	fi
else
	EXEEXT_FOR_BUILD=$EXEEXT
fi
AC_MSG_RESULT([$EXEEXT_FOR_BUILD])
AC_SUBST(EXEEXT_FOR_BUILD)

AC_SUBST(WITH_FTD2XX, $with_ftd2xx)

AC_OUTPUT(Makefile src/Makefile src/helper/Makefile src/jtag/Makefile src/xsvf/Makefile src/target/Makefile src/server/Makefile src/flash/Makefile src/pld/Makefile doc/Makefile)
