mirror of
https://github.com/linux-msm/debugcc.git
synced 2026-02-25 13:12:32 -08:00
8e31500177
APCS clocks are ignored because the logic is a bit too conditional in the downstream clock-8974.c code to be nicely integrated. Signed-off-by: Luca Weiss <luca@lucaweiss.eu>
66 lines
1.2 KiB
Meson
66 lines
1.2 KiB
Meson
# SPDX-License-Identifier: BSD-3-Clause
|
|
|
|
project('debugcc',
|
|
'c',
|
|
license: ['BSD-3-Clause'],
|
|
meson_version : '>= 0.61.0', # for install_symlink
|
|
default_options: [
|
|
'buildtype=release',
|
|
]
|
|
)
|
|
|
|
platforms = [
|
|
'ipq8064',
|
|
'msm8936',
|
|
'msm8974',
|
|
'msm8994',
|
|
'msm8996',
|
|
'msm8998',
|
|
'qcm2290',
|
|
'qcs404',
|
|
'sc7180',
|
|
'sc8280xp',
|
|
'sdm845',
|
|
'sm6115',
|
|
'sm6125',
|
|
'sm6350',
|
|
'sm6375',
|
|
'sm8150',
|
|
'sm8250',
|
|
'sm8350',
|
|
'sm8450',
|
|
'sm8550',
|
|
'sm8650',
|
|
]
|
|
|
|
debugcc_srcs = [
|
|
'debugcc.c',
|
|
]
|
|
|
|
platform_defs = []
|
|
platform_array = []
|
|
|
|
foreach p: platforms
|
|
debugcc_srcs += p + '.c'
|
|
platform_defs += 'extern struct debugcc_platform ' + p + '_debugcc;'
|
|
platform_array += '\t&' + p + '_debugcc,'
|
|
|
|
install_symlink(p + '-debugcc',
|
|
install_dir: get_option('bindir'),
|
|
pointing_to: 'debugcc')
|
|
endforeach
|
|
|
|
platforms = configuration_data()
|
|
platforms.set('PLATFORM_DEFS', '\n'.join(platform_defs))
|
|
platforms.set('PLATFORM_ARRAY', '\n'.join(platform_array))
|
|
|
|
debugcc_srcs += configure_file(
|
|
input: 'platforms.c.in',
|
|
output: 'platforms.c',
|
|
configuration: platforms)
|
|
|
|
executable('debugcc',
|
|
debugcc_srcs,
|
|
link_args: ['-static','-static-libgcc'],
|
|
install: true)
|