# -*- python -*-

Import('env')
import sys

name = "Plugin_VideoOGL"

files = [
	'BPFunctions.cpp',
	'DLCache.cpp',
	'RasterFont.cpp',
	'Render.cpp',
	'TextureMngr.cpp',
	'NativeVertexFormat.cpp',
	'PixelShaderCache.cpp',
	'VertexShaderCache.cpp',
	'TextureConverter.cpp',
	'VertexManager.cpp',
	'VertexLoaderManager.cpp',
	'XFB.cpp',
	'PostProcessing.cpp',
	'FramebufferManager.cpp',
	'main.cpp',
	'GLUtil.cpp'
	]

libs = [
	'videocommon', 'GLEW', 'SOIL', 'common'
	]

gfxenv = env.Clone()

if sys.platform != 'darwin':
	if gfxenv['HAVE_OPENCL']:
		libs += [ 'OpenCL']

if gfxenv['HAVE_WX']:
	files += [
		'GUI/ConfigDlg.cpp',
		'Debugger/Debugger.cpp',
		]

if sys.platform == 'darwin':
	files += [ 'cocoaGL.m' ]

if sys.platform == 'win32':
	files += [ 'OS/Win32.cpp' ]
	libs += [ env['base_dir'] + '/Externals/Cg/' ]	
	gfxenv['CPPPATH'] += libs

gfxenv.SharedLibrary(
	env['plugin_dir']+name,
	files,
	LIBS =  libs + gfxenv['LIBS']
	)
