You've already forked UnrealEngineUWP
mirror of
https://github.com/izzy2lost/UnrealEngineUWP.git
synced 2026-03-26 18:15:20 -07:00
ee64a28f30
This change is the copy-up of work from //UE5/Dev-ParallelRendering to unify the various RHI texture types - The separate RHI texture types (FRHITexture2D, FRHITexture2DArray, FRHITexture3D, FRHITextureCube, FRHITextureCubeArray) have been replaced with a single type: FRHITexture. - Includes the required refactoring / fixes for the various platform RHIs. The old texture types are still supported via typedefs, but will soon be marked deprecated. Future rendering code should make use of the FRHITexture type instead. #jira UE-139559 #rb Mihnea.Balta #preflight 622f3af819287beb2c3047f6 #robomerge[FN_ENGINEMERGE] DEV-NC [CL 19371962 by Luke Thatcher in ue5-main branch]
116 lines
3.0 KiB
Batchfile
Executable File
116 lines
3.0 KiB
Batchfile
Executable File
@echo off
|
|
setlocal ENABLEEXTENSIONS
|
|
setlocal ENABLEDELAYEDEXPANSION
|
|
set KEY_NAME=HKLM\SOFTWARE\Android Studio
|
|
set VALUE_NAME=Path
|
|
set STUDIO_PATH=
|
|
|
|
IF "%5" == "-noninteractive" (
|
|
set PAUSE=
|
|
) ELSE (
|
|
set PAUSE=pause
|
|
)
|
|
|
|
SET PLATFORMS_VERSION=%1
|
|
SET BUILDTOOLS_VERSION=%2
|
|
SET CMAKE_VERSION=%3
|
|
SET NDK_VERSION=%4
|
|
|
|
rem hardcoded versions for compatibility with non-Turnkey manual running
|
|
if "%PLATFORMS_VERSION%" == "" SET PLATFORMS_VERSION=android-30
|
|
if "%BUILDTOOLS_VERSION%" == "" SET BUILDTOOLS_VERSION=30.0.3
|
|
if "%CMAKE_VERSION%" == "" SET CMAKE_VERSION=3.10.2.4988404
|
|
if "%NDK_VERSION%" == "" SET NDK_VERSION=21.4.7075529
|
|
|
|
|
|
FOR /F "tokens=2*" %%A IN ('REG.exe query "%KEY_NAME%" /v "%VALUE_NAME%"') DO (set STUDIO_PATH=%%B)
|
|
|
|
IF EXIST "%STUDIO_PATH%" (
|
|
echo.
|
|
) ELSE (
|
|
echo Android Studio not installed, please download Android Studio 3.5.3 from https://developer.android.com/studio
|
|
%PAUSE%
|
|
exit /b 1
|
|
)
|
|
echo Android Studio Path: %STUDIO_PATH%
|
|
|
|
set VALUE_NAME=SdkPath
|
|
set STUDIO_SDK_PATH=
|
|
FOR /F "tokens=2*" %%A IN ('REG.exe query "%KEY_NAME%" /v "%VALUE_NAME%"') DO (set STUDIO_SDK_PATH=%%B)
|
|
|
|
set ANDROID_LOCAL=%LOCALAPPDATA%\Android\Sdk
|
|
|
|
if "%STUDIO_SDK_PATH%" == "" (
|
|
IF EXIST "%ANDROID_LOCAL%" (
|
|
set STUDIO_SDK_PATH=%ANDROID_LOCAL%
|
|
) ELSE (
|
|
IF EXIST "%ANDROID_HOME%" (
|
|
set STUDIO_SDK_PATH=%ANDROID_HOME%
|
|
) ELSE (
|
|
echo Unable to locate local Android SDK location. Did you run Android Studio after installing?
|
|
%PAUSE%
|
|
exit /b 2
|
|
)
|
|
)
|
|
)
|
|
echo Android Studio SDK Path: %STUDIO_SDK_PATH%
|
|
|
|
if DEFINED ANDROID_HOME (set a=1) ELSE (
|
|
set ANDROID_HOME=%STUDIO_SDK_PATH%
|
|
setx ANDROID_HOME "%STUDIO_SDK_PATH%"
|
|
)
|
|
if DEFINED JAVA_HOME (set a=1) ELSE (
|
|
set JAVA_HOME=%STUDIO_PATH%\jre
|
|
setx JAVA_HOME "%STUDIO_PATH%\jre"
|
|
)
|
|
set NDKINSTALLPATH=%STUDIO_SDK_PATH%\ndk\%NDK_VERSION%
|
|
set PLATFORMTOOLS=%STUDIO_SDK_PATH%\platform-tools;%STUDIO_SDK_PATH%\tools
|
|
|
|
set KEY_NAME=HKCU\Environment
|
|
set VALUE_NAME=Path
|
|
set USERPATH=
|
|
|
|
FOR /F "tokens=2*" %%A IN ('REG.exe query "%KEY_NAME%" /v "%VALUE_NAME%"') DO (set USERPATH=%%B)
|
|
|
|
where.exe /Q adb.exe
|
|
IF /I "%ERRORLEVEL%" NEQ "0" (
|
|
echo Current user path: "%USERPATH%"
|
|
setx PATH "%USERPATH%;%PLATFORMTOOLS%"
|
|
echo Added %PLATFORMTOOLS% to path
|
|
)
|
|
|
|
set SDKMANAGER=%STUDIO_SDK_PATH%\tools\bin\sdkmanager.bat
|
|
IF EXIST "%SDKMANAGER%" (
|
|
echo Using sdkmanager: %SDKMANAGER%
|
|
) ELSE (
|
|
set SDKMANAGER=%STUDIO_SDK_PATH%\cmdline-tools\latest\bin\sdkmanager.bat
|
|
IF EXIST "!SDKMANAGER!" (
|
|
echo Using sdkmanager: !SDKMANAGER!
|
|
) ELSE (
|
|
echo Unable to locate sdkmanager.bat. Did you run Android Studio and install cmdline-tools after installing?
|
|
%PAUSE%
|
|
exit /b 3
|
|
)
|
|
)
|
|
|
|
call "%SDKMANAGER%" "platform-tools" "platforms;%PLATFORMS_VERSION%" "build-tools;%BUILDTOOLS_VERSION%" "cmake;%CMAKE_VERSION%" "ndk;%NDK_VERSION%"
|
|
|
|
IF /I "%ERRORLEVEL%" NEQ "0" (
|
|
echo Update failed. Please check the Android Studio install.
|
|
%PAUSE%
|
|
exit /b 4
|
|
)
|
|
|
|
if EXIST "%NDKINSTALLPATH%" (
|
|
echo Success!
|
|
setx NDKROOT "%NDKINSTALLPATH%"
|
|
setx NDK_ROOT "%NDKINSTALLPATH%"
|
|
) ELSE (
|
|
echo Update failed. Did you accept the license agreement?
|
|
%PAUSE%
|
|
exit /b 5
|
|
)
|
|
|
|
%PAUSE%
|
|
exit /b 0
|