Files
UnrealEngineUWP/Engine/Extras/VisualStudioDebugging/InstallVisualizers.bat
mark lintott 53511dcacd #jira UE-104748
#rb Ben.Marsh

Renamed UE4.natvis to Unreal.natvis
Fixed up Project File Generator within the Unreal Build Tool

[CL 15009828 by mark lintott in ue5-main branch]
2021-01-07 10:21:33 -04:00

41 lines
1.3 KiB
Batchfile
Executable File

@echo off
set FoundVSInstance=0
rem Change to directory where batch file is located. We'll restore this later with "popd"
pushd %~dp0
if "%VS140COMNTOOLS%" neq "" (
set FoundVSInstance=1
mkdir "%USERPROFILE%\Documents\Visual Studio 2015\Visualizers"
copy Unreal.natvis "%USERPROFILE%\Documents\Visual Studio 2015\Visualizers"
copy Unreal_Android_Nsight.dat "%VS140COMNTOOLS%\..\IDE\Extensions\NVIDIA\Nsight Tegra\3.4\Debuggers\Visualizers"
echo Installed visualizers for Visual Studio 2015
)
if "%VS120COMNTOOLS%" neq "" (
set FoundVSInstance=1
mkdir "%USERPROFILE%\Documents\Visual Studio 2013\Visualizers"
copy Unreal.natvis "%USERPROFILE%\Documents\Visual Studio 2013\Visualizers"
echo Installed visualizers for Visual Studio 2013
)
if "%VS110COMNTOOLS%" neq "" (
set FoundVSInstance=1
mkdir "%USERPROFILE%\Documents\Visual Studio 2012\Visualizers"
copy Unreal.natvis "%USERPROFILE%\Documents\Visual Studio 2012\Visualizers"
echo Installed visualizers for Visual Studio 2012
)
for /d %%i in (..\..\Platforms\*) do (
if exist "%%i\Extras\VisualStudioDebugging\InstallVisualizer.bat" (
call "%%i\Extras\VisualStudioDebugging\InstallVisualizer.bat"
)
)
if "%FoundVSInstance%" equ "0" (
echo ERROR: Could not find a valid version of Visual Studio installed (2012, 2013, 2015)
)
popd
pause
exit /b