You've already forked UnrealEngineUWP
mirror of
https://github.com/izzy2lost/UnrealEngineUWP.git
synced 2026-03-26 18:15:20 -07:00
400631a9ab
#rnx #jira UE-167060 #rb ?? #preflight n/a [CL 22511639 by ryan hummer in ue5-main branch]
43 lines
1.3 KiB
Batchfile
Executable File
43 lines
1.3 KiB
Batchfile
Executable File
@echo off
|
|
setlocal
|
|
pushd "%~dp0"
|
|
|
|
rem Figure out if we should append the -prompt argument
|
|
set PROMPT_ARGUMENT=
|
|
for %%P in (%*) do if /I "%%P" == "--prompt" goto no_prompt_argument
|
|
for %%P in (%*) do if /I "%%P" == "--force" goto no_prompt_argument
|
|
set PROMPT_ARGUMENT=--prompt
|
|
:no_prompt_argument
|
|
|
|
rem Sync the dependencies...
|
|
.\Engine\Binaries\DotNET\GitDependencies\win-x64\GitDependencies.exe %PROMPT_ARGUMENT% %*
|
|
if %ERRORLEVEL% NEQ 0 goto error
|
|
|
|
rem Setup the git hooks...
|
|
if not exist .git\hooks goto no_git_hooks_directory
|
|
echo Registering git hooks...
|
|
echo #!/bin/sh >.git\hooks\post-checkout
|
|
echo Engine/Binaries/DotNET/GitDependencies/win-x64/GitDependencies.exe %* >>.git\hooks\post-checkout
|
|
echo #!/bin/sh >.git\hooks\post-merge
|
|
echo Engine/Binaries/DotNET/GitDependencies/win-x64/GitDependencies.exe %* >>.git\hooks\post-merge
|
|
:no_git_hooks_directory
|
|
|
|
rem Install prerequisites...
|
|
echo Installing prerequisites...
|
|
start /wait Engine\Extras\Redist\en-us\UEPrereqSetup_x64.exe /quiet /norestart
|
|
|
|
rem Register the engine installation...
|
|
if not exist .\Engine\Binaries\Win64\UnrealVersionSelector-Win64-Shipping.exe goto :no_unreal_version_selector
|
|
.\Engine\Binaries\Win64\UnrealVersionSelector-Win64-Shipping.exe /register
|
|
:no_unreal_version_selector
|
|
|
|
rem Done!
|
|
goto :end
|
|
|
|
rem Error happened. Wait for a keypress before quitting.
|
|
:error
|
|
pause
|
|
|
|
:end
|
|
popd
|