#compdef systemd-delta
# SPDX-License-Identifier: LGPL-2.1-or-later

(( $+functions[_systemd-delta_types] )) ||
_systemd-delta_types() {
    local -a _delta_types
    _delta_types=(masked equivalent redirected overridden unchanged)
    _values -s , "${_delta_types[@]}"
}

_arguments \
    {-h,--help}'[Show this help]' \
    '--version[Show package version]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--diff=[Show a diff when overridden files differ]:boolean:(1 0)' \
    {-t+,--type=}'[Only display a selected set of override types]:types:_systemd-delta_types' \
    ':SUFFIX:(tmpfiles.d sysctl.d systemd/system)'
