ARMSX1/android/app/build.gradle

plugins {
    id 'com.android.application'
}

android {
    namespace 'com.nanodata.armsx'
    compileSdk rootProject.ext.compileSdkVersion

    defaultConfig {
        applicationId 'com.nanodata.armsx'
        minSdk rootProject.ext.minSdkVersion
        targetSdk rootProject.ext.targetSdkVersion
        versionCode 1
        versionName '0.1.0'
        vectorDrawables.useSupportLibrary = true
    }

    signingConfigs {
        debug {
            storeFile file("debug.keystore")
            storePassword "android"
            keyAlias "androiddebugkey"
            keyPassword "android"
        }
    }

    buildTypes {
        debug {
            matchingFallbacks = ['release']
        }
        release {
            signingConfig signingConfigs.debug
            minifyEnabled false
            shrinkResources false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_17
        targetCompatibility JavaVersion.VERSION_17
    }

    packagingOptions {
        resources {
            excludes += ['META-INF/DEPENDENCIES']
        }
    }

    buildFeatures {
        buildConfig true
    }

    sourceSets {
        main {
            java.srcDirs += ['../../third_party/SDL/android-project/app/src/main/java']
            res.srcDirs += ['src/main/res', '../../third_party/SDL/android-project/app/src/main/res']
            assets.srcDirs += ['src/main/assets']
            jniLibs.srcDirs += ['src/main/jniLibs']
        }
    }
}

dependencies {
    implementation 'androidx.appcompat:appcompat:1.7.0'
}

def repoRootDir = rootProject.projectDir.parentFile
def nativeOutput = file("$projectDir/src/main/jniLibs/arm64-v8a/libarmsx.so")
def skipNativePrepare = System.getenv("ARMSX_SKIP_NATIVE_PREPARE") == "1"

tasks.register("prepareNativeBinaries") {
    group = "native"
    description = "Build SDL2/libarmsx via build.sh android."
    inputs.file(new File(repoRootDir, "build.sh"))
    outputs.file(nativeOutput)
    onlyIf { !skipNativePrepare }
    doLast {
        exec {
            workingDir repoRootDir
            commandLine "./build.sh", "android"
        }
    }
}

preBuild.dependsOn(tasks.named("prepareNativeBinaries"))