mirror of
https://github.com/AdaCore/cpython.git
synced 2026-02-12 12:57:15 -08:00
986b7ffc65
The Windows build now depends on Python 3.6 to fetch externals, but it will be downloaded via NuGet (which is downloaded via PowerShell) if it is not available via `py -3.6`. This means the only thing that must be installed on a modern Windows box to do a full build of CPython with all extensions is Visual Studio. Cherry-picked from51599e2bdd, parts of40a23e8899, parts of68d663cf85,d5cd21d75a, and possibly others that I've missed. Also: * Rename db -> bsddb for disambiguity * Update sqlite3 to 3.14.2.0 since it's the version we use on 3.x, and it's simpler to just use it than to also upload the old version to cpython-source-deps * Add PCbuild/*.ilk to .gitignore
136 lines
4.0 KiB
Batchfile
136 lines
4.0 KiB
Batchfile
@echo off
|
|
setlocal
|
|
|
|
pushd %~dp0
|
|
|
|
set this=%~n0
|
|
|
|
call ..\PCBuild\find_python.bat %PYTHON%
|
|
if not defined SPHINXBUILD if defined PYTHON (
|
|
%PYTHON% -c "import sphinx" > nul 2> nul
|
|
if errorlevel 1 (
|
|
echo Installing sphinx with %PYTHON%
|
|
%PYTHON% -m pip install sphinx
|
|
if errorlevel 1 exit /B
|
|
)
|
|
set SPHINXBUILD=%PYTHON% -c "import sphinx, sys; sys.argv[0] = 'sphinx-build'; sphinx.main()"
|
|
)
|
|
|
|
if not defined PYTHON set PYTHON=py
|
|
if not defined SPHINXBUILD set SPHINXBUILD=sphinx-build
|
|
|
|
if DEFINED ProgramFiles(x86) set _PRGMFLS=%ProgramFiles(x86)%
|
|
if NOT DEFINED ProgramFiles(x86) set _PRGMFLS=%ProgramFiles%
|
|
if "%HTMLHELP%" EQU "" set HTMLHELP=%_PRGMFLS%\HTML Help Workshop\hhc.exe
|
|
|
|
if "%DISTVERSION%" EQU "" for /f "usebackq" %%v in (`%PYTHON% tools/extensions/patchlevel.py`) do set DISTVERSION=%%v
|
|
|
|
if "%BUILDDIR%" EQU "" set BUILDDIR=build
|
|
|
|
rem Targets that don't require sphinx-build
|
|
if "%1" EQU "" goto help
|
|
if "%1" EQU "help" goto help
|
|
if "%1" EQU "check" goto check
|
|
if "%1" EQU "serve" goto serve
|
|
if "%1" == "clean" (
|
|
rmdir /q /s %BUILDDIR%
|
|
goto end
|
|
)
|
|
|
|
%SPHINXBUILD% 2> nul
|
|
if errorlevel 9009 (
|
|
echo.
|
|
echo.The 'sphinx-build' command was not found. Make sure you have Sphinx
|
|
echo.installed, then set the SPHINXBUILD environment variable to point
|
|
echo.to the full path of the 'sphinx-build' executable. Alternatively you
|
|
echo.may add the Sphinx directory to PATH.
|
|
echo.
|
|
echo.If you don't have Sphinx installed, grab it from
|
|
echo.http://sphinx-doc.org/
|
|
goto end
|
|
)
|
|
|
|
rem Targets that do require sphinx-build and have their own label
|
|
if "%1" EQU "htmlview" goto htmlview
|
|
|
|
rem Everything else
|
|
goto build
|
|
|
|
:help
|
|
echo.usage: %this% BUILDER [filename ...]
|
|
echo.
|
|
echo.Call %this% with the desired Sphinx builder as the first argument, e.g.
|
|
echo.``%this% html`` or ``%this% doctest``. Interesting targets that are
|
|
echo.always available include:
|
|
echo.
|
|
echo. Provided by Sphinx:
|
|
echo. html, htmlhelp, latex, text
|
|
echo. suspicious, linkcheck, changes, doctest
|
|
echo. Provided by this script:
|
|
echo. clean, check, serve, htmlview
|
|
echo.
|
|
echo.All arguments past the first one are passed through to sphinx-build as
|
|
echo.filenames to build or are ignored. See README.txt in this directory or
|
|
echo.the documentation for your version of Sphinx for more exhaustive lists
|
|
echo.of available targets and descriptions of each.
|
|
echo.
|
|
echo.This script assumes that the SPHINXBUILD environment variable contains
|
|
echo.a legitimate command for calling sphinx-build, or that sphinx-build is
|
|
echo.on your PATH if SPHINXBUILD is not set. Options for sphinx-build can
|
|
echo.be passed by setting the SPHINXOPTS environment variable.
|
|
goto end
|
|
|
|
:build
|
|
if NOT "%PAPER%" == "" (
|
|
set SPHINXOPTS=-D latex_elements.papersize=%PAPER% %SPHINXOPTS%
|
|
)
|
|
cmd /C "%SPHINXBUILD% %SPHINXOPTS% -b%1 -dbuild\doctrees . %BUILDDIR%\%*"
|
|
|
|
if "%1" EQU "htmlhelp" (
|
|
if not exist "%HTMLHELP%" (
|
|
echo.
|
|
echo.The HTML Help Workshop was not found. Set the HTMLHELP variable
|
|
echo.to the path to hhc.exe or download and install it from
|
|
echo.http://msdn.microsoft.com/en-us/library/ms669985
|
|
rem Set errorlevel to 1 and exit
|
|
cmd /C exit /b 1
|
|
goto end
|
|
)
|
|
cmd /C "%HTMLHELP%" build\htmlhelp\python%DISTVERSION:.=%.hhp
|
|
rem hhc.exe seems to always exit with code 1, reset to 0 for less than 2
|
|
if not errorlevel 2 cmd /C exit /b 0
|
|
)
|
|
|
|
echo.
|
|
if errorlevel 1 (
|
|
echo.Build failed (exit code %ERRORLEVEL%^), check for error messages
|
|
echo.above. Any output will be found in %BUILDDIR%\%1
|
|
) else (
|
|
echo.Build succeeded. All output should be in %BUILDDIR%\%1
|
|
)
|
|
goto end
|
|
|
|
:htmlview
|
|
if NOT "%2" EQU "" (
|
|
echo.Can't specify filenames to build with htmlview target, ignoring.
|
|
)
|
|
cmd /C %this% html
|
|
|
|
if EXIST %BUILDDIR%\html\index.html (
|
|
echo.Opening %BUILDDIR%\html\index.html in the default web browser...
|
|
start %BUILDDIR%\html\index.html
|
|
)
|
|
|
|
goto end
|
|
|
|
:check
|
|
cmd /C %PYTHON% tools\rstlint.py -i tools
|
|
goto end
|
|
|
|
:serve
|
|
cmd /C %PYTHON% ..\Tools\scripts\serve.py %BUILDDIR%\html
|
|
goto end
|
|
|
|
:end
|
|
popd
|